Added Clightd stable releases to aur.

1 files changed, 36 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..587bd73ed683
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Federico Di Pierro <nierro92@gmail.com>
+
+pkgname=clightd
+_gitname=Clightd
+pkgver=3.0
+pkgrel=1
+pkgdesc="Bus interface to change screen brightness and capture frames from webcam."
+arch=('i686' 'x86_64')
+url="https://github.com/FedeDP/${_gitname}"
+license=('GPL')
+depends=('systemd>=221' 'linux-api-headers' 'libx11' 'libxrandr' 'libxext' 'polkit' 'libxss' 'ddcutil' 'libmodule>=3.1.0')
+makedepends=('git' 'cmake')
+optdepends=('clight: user service to automagically change screen backlight matching ambient brightness.')
+source=("${_gitname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz")
+sha256sums=("a52d340ba4ac01fa115e54ca8f82ea9f7f6863103eef3a517425b42615accca0")
+
+prepare() {
+    cd "${srcdir}/${_gitname}-${pkgver}"
+    mkdir -p build
+}
+
+build() {
+    cd "${srcdir}/${_gitname}-${pkgver}/build"
+    cmake \
+        -G "Unix Makefiles" \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_INSTALL_LIBDIR=lib \
+        -DCMAKE_BUILD_TYPE="Release" \
+        ..
+    make
+}
+
+package() {
+    cd "${srcdir}/${_gitname}-${pkgver}/build"
+    make DESTDIR="$pkgdir" install
+}