initial commit

1 files changed, 42 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..a20b756c3127
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: Florent Thiéry <fthiery@gmail.com>
+
+pkgname=cockpit-networkmanager
+pkgver=150
+pkgrel=1
+pkgdesc='A systemd web based user interface for Linux servers (minimal setup with system graphs, journalctl, storage, network, user accounts, systemd services and terminal)'
+arch=(i686 x86_64 armv6h armv7h)
+url='http://www.cockpit-project.org/'
+license=(LGPL2.1)
+conflicts=(cockpit-git cockpit)
+depends=(libssh krb5 sshpass accountsservice perl-json perl-locale-po json-glib glib-networking networkmanager)
+# udisks support disables some features
+#http://cockpit-project.org/guide/latest/feature-storaged.html
+optdepends=('udisks2: disk stats support')
+makedepends=(git intltool python2-pyscss gtk-doc perl-javascript-minifier-xs gobject-introspection networkmanager libgsystem xmlto npm tar)
+source=(https://github.com/cockpit-project/cockpit/releases/download/${pkgver}/cockpit-${pkgver}.tar.xz
+	https://github.com/cockpit-project/cockpit/releases/download/${pkgver}/cockpit-cache-${pkgver}.tar.xz)
+noextract=(cockpit-${pkgver}.tar.xz)
+sha1sums=('ba1266d4beff77d0967c06ecbec4ed3767a7ca5b'
+          '1ea5dd6189d2b6b6aafbcec2f0c0b0075db5eeb4')
+
+prepare() {
+  cd $srcdir
+
+  #bsdtar can't extract cockpit
+  tar -xf cockpit-${pkgver}.tar.xz
+}
+
+build() {
+  cd cockpit-${pkgver}
+  ./configure --prefix=/usr --sbindir=/usr/bin --sysconfdir=/etc --localstatedir=/var --disable-pcp --disable-doc
+  make
+}
+
+package() {
+  cd cockpit-${pkgver}
+  make DESTDIR="$pkgdir" install
+  cd $pkgdir
+  for d in docker kdump kubernetes machines ostree packagekit pcp playground realmd selinux sosreport subscriptions tuned; do
+      rm -r usr/share/cockpit/$d;
+  done
+}