initial import

1 files changed, 40 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..32797670d794
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,40 @@
+# Maintainer: tinywrkb <tinywrkb@gmail.com>
+
+_pkgname=coda-bits
+pkgname=${_pkgname}-git
+pkgver=r6.5840a95
+pkgrel=1
+pkgdesc="Bits & pieces of information about CODA VPUs"
+arch=(x86_64)
+url="https://github.com/pH5/${_pkgname}"
+license=(ISC)
+depends=(glibc)
+makedepends=(git meson)
+source=("${_pkgname}::git+${url}.git"
+		000-packaging.patch)
+sha256sums=('SKIP'
+		'SKIP')
+
+pkgver() {
+  cd ${_pkgname}
+  set -o pipefail
+  git describe --long 2> /dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd ${_pkgname}
+  patch -Np1 -i "${srcdir}"/000-packaging.patch
+}
+
+build() {
+  cd ${_pkgname}
+  meson --prefix=/usr build
+  ninja -C build
+}
+
+package() {
+  cd ${_pkgname}
+  DESTDIR="$pkgdir" meson install -C build
+  install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}