Update to CORE 7.0.1 release.

Required a bit of reworking due to project update to use Poetry to
manage Python dependencies.  Also cleaned up a few unnecessary
dependencies.

Thanks to @Rucikir for dealing with this.

1 files changed, 39 insertions, 12 deletions

diff --git a/PKGBUILD b/PKGBUILD
index 02f38dee710c..3f56dae48083 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,34 +1,61 @@
 # Maintainer: Tom Wambold <tom5760@gmail.com>
+# Contributor: Antonin Décimo <antonin dot decimo at gmail dot com>
 pkgname=core
-pkgver=6.5.0
+pkgver=7.0.1
 pkgrel=1
 pkgdesc="Common Open Research Emulator"
 arch=('i686' 'x86_64')
 url="https://github.com/coreemu/core/"
 license=('BSD')
-depends=('bridge-utils' 'ebtables' 'ethtool' 'fabric' 'iproute2' 'libev'
-  'openvswitch' 'procps-ng' 'python3' 'python-future' 'python-grpcio'
-  'python-lxml' 'python-mako' 'python-netaddr' 'python-pillow' 'python-pyproj'
-  'python-yaml' 'tkimg' 'util-linux' 'xterm')
-makedepends=('help2man' 'imagemagick' 'python-grpcio-tools' 'openvswitch')
-optdepends=('openvswitch: Open vSwitch support')
+depends=('ebtables' 'ethtool' 'fabric' 'iproute2' 'libev' 'python'
+         'python-grpcio' 'python-invoke' 'python-lxml' 'python-mako'
+         'python-netaddr' 'python-pillow' 'python-protobuf' 'python-pyproj'
+         'python-yaml')
+makedepends=('help2man' 'imagemagick' 'python-dephell' 'python-grpcio-tools'
+             'python-setuptools')
+optdepends=('openvswitch: Open vSwitch SDN support'
+            'tkimg: Thumbnail support in Tcl/Tk GUI')
 backup=('etc/core/core.conf')
-source=("https://github.com/coreemu/core/archive/release-$pkgver.tar.gz")
-md5sums=('a2d29adb499f35a2d9a1ef0e31409160')
+source=("https://github.com/coreemu/core/archive/release-$pkgver.tar.gz"
+        'core-daemon.service')
+md5sums=('04e26fdb070ceb2532ea08c43c1f01b2'
+         '91be51f861a0e166c643a885d1bf1eba')
+
+prepare() {
+  cd "$srcdir/core-release-$pkgver/daemon"
+
+  dephell deps convert --from pyproject.toml --to setup.py
+}
 
 build() {
   cd "$srcdir/core-release-$pkgver"
 
   ./bootstrap.sh
-  ./configure              \
-    --prefix=/usr          \
-    --with-startup=systemd
+  ./configure --prefix=/usr
   make
+
+  cd daemon
+  python setup.py build
 }
 
 package() {
   cd "$srcdir/core-release-$pkgver"
   make DESTDIR="$pkgdir/" install
+
+  cd daemon
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+  mkdir -p "$pkgdir/usr/bin"
+  cp -r scripts/* "$pkgdir/usr/bin"
+
+  mkdir -p "$pkgdir/usr/share/core"
+  cp -r examples "$pkgdir/usr/share/core"
+
+  mkdir -p "$pkgdir/etc/core"
+  cp data/core.conf data/logging.conf "$pkgdir/etc/core"
+
+  mkdir -p "$pkgdir/usr/lib/systemd/system"
+  cp "$srcdir/core-daemon.service" "$pkgdir/usr/lib/systemd/system"
 }
 
 # vim:set ts=2 sw=2 et: