cramino ver 0.9.9

1 files changed, 39 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..d4dacceab226
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,39 @@
+# Maintainer: bipin kumar <kbipinkumar@pm.me>
+pkgname=cramino
+pkgver=0.9.9
+pkgrel=1
+pkgdesc='A fast tool for BAM/CRAM quality evaluation of long reads. https://doi.org/10.1093/bioinformatics/btad311'
+arch=(x86_64)
+depends=('gcc-libs' 'glibc' 'bzip2')
+makedepends=('git' 'rust' 'cmake')
+url='https://github.com/wdecoster/cramino'
+license=('MIT')
+options=(!lto)
+source=(${pkgname}-${pkgver}.tar.gz::https://github.com/wdecoster/cramino/archive/refs/tags/v${pkgver}.tar.gz)
+sha256sums=('4892fcee0a5b4b0b7c49ed4f5f54168a15d5c0419e3eacee0d6155a207e194a1')
+
+prepare() {
+    cd ${pkgname}-${pkgver}
+    export RUSTUP_TOOLCHAIN=stable
+    cargo fetch  --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+    cd ${pkgname}-${pkgver}
+    export RUSTUP_TOOLCHAIN=stable
+    export CARGO_TARGET_DIR=target
+    cargo build --frozen --release --all-features
+}
+
+check() {
+    cd ${pkgname}-${pkgver}
+    export RUSTUP_TOOLCHAIN=stable
+    cargo test --frozen --all-features
+}
+
+package() {
+    cd ${pkgname}-${pkgver}
+    install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$pkgname"
+    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
+}
+