dbus-typenum-git: initialize package

New packet for the dbus-typenum project, which provides a D-Bus type
enumeration library and command-line tool.

Signed-off-by: David Herrmann <dh.herrmann@gmail.com>

1 files changed, 38 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..b59ecb9ad312
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: David Herrmann <dh.herrmann@gmail.com>
+
+_pkgorg=cherry-pick
+_pkgname=dbus-typenum
+pkgdesc='D-Bus Type Enumerator'
+pkgver=r5.2c2fea5
+pkgrel=1
+
+pkgname=$_pkgname-git
+arch=('i686' 'x86_64')
+url="https://github.com/$_pkgorg/$_pkgname"
+license=('Apache')
+depends=('glibc')
+makedepends=('git' 'meson')
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+source=("$pkgname::git+https://github.com/$_pkgorg/$_pkgname")
+md5sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+  rm -Rf "build"
+  meson --prefix=/usr --buildtype=release "$pkgname" "build"
+  ninja -v -C "build"
+}
+
+check() {
+  ninja -v -C "build" test
+}
+
+package() {
+  DESTDIR="$pkgdir" ninja -v -C "build" install
+}