Add to AUR

1 files changed, 38 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..4c4736afb594
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: Caltlgin Stsodaat <contact@fossdaily.xyz>
+
+pkgname='dnsx'
+pkgver=1.0.0
+pkgrel=1
+pkgdesc='Fast and multi-purpose DNS toolkit'
+arch=('x86_64')
+url='https://github.com/projectdiscovery/dnsx'
+license=('MIT')
+makedepends=('go')
+provides=("${pkgname}")
+source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
+sha256sums=('112f81c2e5efc73103bebfb9e8f7db0c7e7e9a95ba432625a5469cfe0a104d06')
+
+prepare() {
+  export GOPATH="${srcdir}/gopath"
+  go clean -modcache
+}
+
+build() {
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+  #export CGO_LDFLAGS="${LDFLAGS}"
+  export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
+
+  cd "${pkgname}-${pkgver}/cmd/${pkgname}"
+  go build -v -o "${pkgname}" .
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  install -Dvm755 "cmd/${pkgname}/${pkgname}" -t "${pkgdir}/usr/bin"
+  install -Dvm644 'README.md' -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dvm644 'LICENSE.md' "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+# vim: ts=2 sw=2 et: