init

1 files changed, 64 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..62b51908ac00
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,64 @@
+# Maintainer: giantdwarf <17hoehbr@gmail.com>
+
+pkgbase=dxvk-async-git
+pkgname=('dxvk-async-git')
+pkgver=1.9.4.r106.gb42c0725
+pkgrel=1
+pkgdesc="A Vulkan-based compatibility layer for Direct3D 9/10/11 which allows running 3D applications on Linux using Wine. Windows DLL version)"
+arch=('x86_64')
+url="https://github.com/Sporif/dxvk-async.git"
+license=('zlib/libpng')
+depends=('vulkan-icd-loader' 'wine>=4.0rc1' 'lib32-vulkan-icd-loader')
+provides=("dxvk" "d9vk" "dxvk=$pkgver")
+makedepends=('ninja' 'meson>=0.43' 'glslang' 'mingw-w64-gcc' 'git' 'wine')
+conflicts=('d9vk-mingw-git' 'd9vk-bin' 'd9vk-winelib-git' "dxvk-bin" "dxvk-git" "dxvk-wine32-git" "dxvk-wine64-git" "dxvk-win32-git" "dxvk-win64-git" "dxvk-winelib-git" "dxvk-mingw-git")
+options=(!strip !buildflags staticlibs)
+source=("git+https://github.com/doitsujin/dxvk.git"
+        "git+https://github.com/Sporif/dxvk-async.git"
+        "dxvk.conf")
+sha256sums=('SKIP'
+            'SKIP'
+            'SKIP')
+
+pkgver() {
+    cd dxvk
+    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/v//g'
+}
+
+prepare() {
+    cd "${srcdir}/dxvk/"
+    patch --forward --strip=1 --input="${srcdir}/dxvk-async/dxvk-async.patch"
+}
+
+build() {
+    meson dxvk "build/x64" \
+        --cross-file dxvk/build-win64.txt \
+        --prefix "/usr/share/dxvk/x64" \
+        --bindir "" --libdir "" \
+        --buildtype "release" \
+        --strip \
+        -D enable_tests=false
+    ninja -C "build/x64"
+
+    meson dxvk "build/x32" \
+        --cross-file dxvk/build-win32.txt \
+        --prefix "/usr/share/dxvk/x32" \
+        --bindir "" --libdir "" \
+        --buildtype "release" \
+        --strip \
+        -D enable_tests=false
+    ninja -C "build/x32"
+}
+
+package_dxvk-async-git() {
+        arch=('x86_64')
+        conflicts=("dxvk-bin" "dxvk-mingw-git")
+        DESTDIR="$pkgdir" ninja -C "build/x32" install
+        DESTDIR="$pkgdir" ninja -C "build/x64" install
+        install -Dm 644 dxvk/setup_dxvk.sh "$pkgdir/usr/share/dxvk/setup_dxvk.sh"
+        mkdir -p "$pkgdir/usr/bin"
+        ln -s /usr/share/dxvk/setup_dxvk.sh "$pkgdir/usr/bin/setup_dxvk"
+        chmod +x "$pkgdir/usr/share/dxvk/setup_dxvk.sh"
+        # Async variable
+        install -Dm644 "$srcdir/dxvk.conf" "$pkgdir/etc/environment.d/dxvk.conf"
+}
\ No newline at end of file