Initial commit: 4.25 (2022-09)

1 files changed, 37 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..d2d78661cfcf
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: Mattia Moffa <mattia [at] moffa [dot] xyz>
+# Maintainer: Morgenstern <charles [at] charlesbwise [dot] com>
+
+pkgname=eclipse-dsl
+epoch=2
+pkgver=4.25
+pkgrel=1
+_release=2022-09/R
+pkgdesc="Highly extensible IDE (Java and DSL version)"
+arch=('x86_64')
+url="https://www.eclipse.org/"
+license=('EPL')
+depends=('java-environment>=11' webkit2gtk unzip)
+provides=(eclipse=$pkgver-$pkgrel)
+conflicts=(eclipse)
+
+_srcfilename="$pkgname-${_release//\//-}-linux-gtk-$CARCH.tar.gz"
+source=("$_srcfilename::https://www.eclipse.org/downloads/download.php?file=/technology/epp/downloads/release/$_release/$_srcfilename&r=1"
+        "eclipse.desktop")
+sha512sums=('32e16a20c7bada9f10e9b57cfd361e6a6fb2d2a6e4db1783f7d80d613272b10275010ca0efde67a938f696ed5c0e47b1d8db4350ffce77afaf773e5d015c08b4'
+            '542a20e13e7f486c55bfc8e22a9da6f4100125809de6b0a2ecdd95e2ca6a242d4dd02d0eeec328c3a7a96bb4a31d2c0e2c7a8cbdfae7f606c46b8029523f8da2')
+
+backup=('usr/lib/eclipse/eclipse.ini')
+
+package() {
+  install -d "${pkgdir}/usr/lib"
+  cp -r "eclipse" "${pkgdir}/usr/lib/eclipse"
+  install -d "${pkgdir}/usr/bin"
+  ln -s "/usr/lib/eclipse/eclipse" "${pkgdir}/usr/bin/eclipse"
+
+  install -Dm0644 "eclipse.desktop" "${pkgdir}/usr/share/applications/eclipse.desktop"
+
+  for i in 16 22 24 32 48 64 128 256 512 1024 ; do
+      install -Dm0644 eclipse/plugins/org.eclipse.platform_${pkgver}*/eclipse$i.png \
+          "${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/eclipse.png"
+  done
+}