init, 16.0.0.alpha.1

Signed-off-by: Yurii Kolesnykov <root@yurikoles.com>

1 files changed, 67 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..ca18a95d974c
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,67 @@
+# Maintainer: Yurii Kolesnykov <root@yurikoles.com>
+# based on aur electron8-bin: Tom Vincent <http://tlvince.com/contact/>
+
+_projectname=electron
+_major=16
+_pkgname=${_projectname}${_major}
+_alpha=1
+_pkgver=${_major}.0.0-alpha.${_alpha}
+pkgver="${_pkgver/-/.}"
+pkgname=${_pkgname}-bin
+pkgrel=1
+pkgdesc="Build cross platform desktop apps with web technologies - version ${_major} - binary version"
+arch=('x86_64' 'i686' 'armv7h' 'aarch64')
+url=https://electronjs.org/
+license=('MIT')
+provides=("${_pkgname}")
+conflicts=("${_pkgname}")
+depends=('c-ares' 'ffmpeg' 'gtk3' 'libevent' 'libnghttp2' 'libxslt' 'minizip'
+         'nss' 're2' 'snappy')
+optdepends=('kde-cli-tools: file deletion support (kioclient5)'
+            'libappindicator-gtk3: StatusNotifierItem support'
+            'pipewire: WebRTC desktop sharing under Wayland'
+            'trash-cli: file deletion support (trash-put)'
+            "xdg-utils: open URLs with desktop's default (xdg-email, xdg-open)")
+_releaseurl="https://github.com/${_projectname}/${_projectname}/releases/download/v${_pkgver}"
+source_x86_64=(
+	"${pkgname}-chromedriver-${pkgver}-${pkgrel}-x86_64.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-x64.zip"
+	"${pkgname}-${pkgver}-${pkgrel}-x86_64.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-x64.zip"
+)
+source_i686=(
+	"${pkgname}-chromedriver-${pkgver}-${pkgrel}-i686.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-ia32.zip"
+	"${pkgname}-${pkgver}-${pkgrel}-i686.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-ia32.zip"
+)
+source_armv7h=(
+	"${pkgname}-chromedriver-${pkgver}-${pkgrel}-armv7h.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-armv7l.zip"
+	"${pkgname}-${pkgver}-${pkgrel}-armv7h.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-armv7l.zip"
+)
+source_aarch64=(
+	"${pkgname}-chromedriver-${pkgver}-${pkgrel}-aarch64.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-arm64.zip"
+	"${pkgname}-${pkgver}-${pkgrel}-aarch64.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-arm64.zip"
+)
+sha256sums_x86_64=('7affa970b5d6347f578dfd8b5c39c5b62e9038d1dc39cb0e78ad8e641d4f2272'
+                   'c222e0aee89d11613676e8367f3c8d118f16e31855c204f6571177cb5c20ede9')
+sha256sums_i686=('872f01f355f70305045b10b50456a2383bc4c08131985899257d51c0b011cc71'
+                 '3e796611dd0bc977c28a9684af1ed726bf1f14446f6eb78f2e1a7d3aa807f5d8')
+sha256sums_armv7h=('6b286570758531855d4b1fb9c760f150032797ddd792b7adcb77fa9b0612db2a'
+                   '6422ae42aa08e320ce474bf8d08034b5917a9cc9a8357aba290cfec6c1f1d484')
+sha256sums_aarch64=('300dac5849c7e86610f9ab4f97170362bbe0018b421edcb0f72a3a86578e959e'
+                    '1dc601871921334812c2a0725c4b56afea5c623b0d6601004699704cf97612b4')
+
+package() {
+	install -dm755 "${pkgdir}/usr/lib/${_pkgname}/"
+	find . -mindepth 1 -maxdepth 1 -type f ! -name "*.zip" ! -name "LICENSE*" -exec cp -r --no-preserve=ownership --preserve=mode -t "${pkgdir}/usr/lib/${_pkgname}/." {} +
+
+	for _folder in 'locales' 'resources' 'swiftshader'; do
+		cp -r --no-preserve=ownership --preserve=mode "${_folder}/" "${pkgdir}/usr/lib/${_pkgname}/${_folder}/"
+	done
+
+	chmod u+s "${pkgdir}/usr/lib/${_pkgname}/chrome-sandbox"
+
+	install -dm755 "${pkgdir}/usr/bin"
+	ln -nfs "/usr/lib/${_pkgname}/${_projectname}" "${pkgdir}/usr/bin/${_pkgname}"
+
+	for _license in 'LICENSE' 'LICENSES.chromium.html'; do
+		install -Dm644 "${_license}" "${pkgdir}/usr/share/licenses/${pkgname}/${_license}"
+	done
+}