19.0.0-alpha.1

Signed-off-by: Yurii Kolesnykov <root@yurikoles.com>

1 files changed, 67 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..81922894e151
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,67 @@
+# Maintainer: Yurii Kolesnykov <root@yurikoles.com>
+# based on aur electron8-bin: Tom Vincent <http://tlvince.com/contact/>
+
+_projectname=electron
+_major=19
+_alpha=1
+_pkgname="${_projectname}${_major}"
+pkgname="${_pkgname}"-bin
+_pkgver="${_major}.0.0-alpha.${_alpha}"
+pkgver="${_pkgver/-/.}"
+pkgrel=1
+pkgdesc="Build cross platform desktop apps with web technologies - binary version ${_major}"
+arch=('x86_64' 'i686' 'armv7h' 'aarch64')
+url=https://electronjs.org/
+license=('MIT')
+provides=("${_pkgname}=${pkgver}" "${_projectname}=${pkgver}")
+conflicts=("${_pkgname}")
+depends=('c-ares' 'ffmpeg' 'gtk3' 'libevent' 'libxslt' 'minizip' 'nss' 're2'
+         'snappy')
+optdepends=('kde-cli-tools: file deletion support (kioclient5)'
+            'libappindicator-gtk3: StatusNotifierItem support'
+            'pipewire: WebRTC desktop sharing under Wayland'
+            'trash-cli: file deletion support (trash-put)'
+            "xdg-utils: open URLs with desktop's default (xdg-email, xdg-open)")
+_releaseurl="https://github.com/${_projectname}/${_projectname}/releases/download/v${_pkgver}"
+source_x86_64=(
+	"${pkgname}-chromedriver-${pkgver}-${pkgrel}-x86_64.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-x64.zip"
+	"${pkgname}-${pkgver}-${pkgrel}-x86_64.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-x64.zip"
+)
+source_i686=(
+	"${pkgname}-chromedriver-${pkgver}-${pkgrel}-i686.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-ia32.zip"
+	"${pkgname}-${pkgver}-${pkgrel}-i686.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-ia32.zip"
+)
+source_armv7h=(
+	"${pkgname}-chromedriver-${pkgver}-${pkgrel}-armv7h.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-armv7l.zip"
+	"${pkgname}-${pkgver}-${pkgrel}-armv7h.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-armv7l.zip"
+)
+source_aarch64=(
+	"${pkgname}-chromedriver-${pkgver}-${pkgrel}-aarch64.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-arm64.zip"
+	"${pkgname}-${pkgver}-${pkgrel}-aarch64.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-arm64.zip"
+)
+sha256sums_x86_64=('b31da51b2a494e08d05413fe6b4d4cce80b0ddb0167e0caeaf12d4028ed6b56b'
+                   'c6b6b6a0f567f7c2052fee5daaa69ac0304c1e9919f9a0955d406a66a98ad34d')
+sha256sums_i686=('00d69cf86e07910d30efdecf1666e3576eaf13bf5f41675ab2ce16f65ab4134d'
+                 '70c94a09bdc5dbfb560164caaadcdc451fb6b4f3aaf9583495b27e1544a8cb8c')
+sha256sums_armv7h=('8c6c895515079ee01b933de686a94d1bc994f1509f54d06b5e299b7afc4a8ebd'
+                   '2d6845c5ed979d03d88ee11d6acfda6ea74f8fffd17e915544a031cb8c812f6f')
+sha256sums_aarch64=('bc4e51bc35ca17870b543757204a5c0f6531b441e41fe72d0d2c8baeacd15ab6'
+                    '7182b153d777e667b57de0171e5e12e32f870d7e9247634cbebb9118049a28c0')
+
+package() {
+	install -dm755 "${pkgdir}/usr/lib/${_pkgname}/"
+	find . -mindepth 1 -maxdepth 1 -type f ! -name "*.zip" ! -name "LICENSE*" -exec cp -r --no-preserve=ownership --preserve=mode -t "${pkgdir}/usr/lib/${_pkgname}/." {} +
+
+	for _folder in 'locales' 'resources' 'swiftshader'; do
+		cp -r --no-preserve=ownership --preserve=mode "${_folder}/" "${pkgdir}/usr/lib/${_pkgname}/${_folder}/"
+	done
+
+	chmod u+s "${pkgdir}/usr/lib/${_pkgname}/chrome-sandbox"
+
+	install -dm755 "${pkgdir}/usr/bin"
+	ln -nfs "/usr/lib/${_pkgname}/${_projectname}" "${pkgdir}/usr/bin/${_pkgname}"
+
+	for _license in 'LICENSE' 'LICENSES.chromium.html'; do
+		install -Dm644 "${_license}" "${pkgdir}/usr/share/licenses/${pkgname}/${_license}"
+	done
+}