init, alpha2

Signed-off-by: Yurii Kolesnykov <root@yurikoles.com>

1 files changed, 55 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..aee645e86a4c
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,55 @@
+# Maintainer: Yurii Kolesnykov <root@yurikoles.com>
+# based on aur electron8-bin: Tom Vincent <http://tlvince.com/contact/>
+
+_projectname=electron
+_major=24
+_pkgname="${_projectname}${_major}"
+pkgname="${_pkgname}"-bin
+_dev=2
+_pkgver="${_major}.0.0-alpha.${_dev}"
+pkgver="${_pkgver/-/.}"
+pkgrel=1
+pkgdesc="Build cross platform desktop apps with web technologies - binary version ${_major}"
+arch=('x86_64' 'aarch64')
+url=https://electronjs.org/
+license=('MIT')
+provides=("${_pkgname}=${pkgver}" "${_projectname}=${pkgver}")
+conflicts=("${_pkgname}")
+depends=('c-ares' 'ffmpeg' 'gtk3' 'libevent' 'libxslt' 'minizip' 'nss' 're2'
+         'snappy')
+optdepends=('kde-cli-tools: file deletion support (kioclient5)'
+            'libappindicator-gtk3: StatusNotifierItem support'
+            'pipewire: WebRTC desktop sharing under Wayland'
+            'trash-cli: file deletion support (trash-put)'
+            "xdg-utils: open URLs with desktop's default (xdg-email, xdg-open)")
+_releaseurl="https://github.com/${_projectname}/${_projectname}/releases/download/v${_pkgver}"
+source_x86_64=(
+	"${pkgname}-chromedriver-${pkgver}-${pkgrel}-x86_64.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-x64.zip"
+	"${pkgname}-${pkgver}-${pkgrel}-x86_64.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-x64.zip"
+)
+source_aarch64=(
+	"${pkgname}-chromedriver-${pkgver}-${pkgrel}-aarch64.zip::${_releaseurl}/chromedriver-v${_pkgver}-linux-arm64.zip"
+	"${pkgname}-${pkgver}-${pkgrel}-aarch64.zip::${_releaseurl}/${_projectname}-v${_pkgver}-linux-arm64.zip"
+)
+sha256sums_x86_64=('ef9bd9f8d4e89bfb0a55eadaaf950c261c654b8921b78c54fdcbfde73af61b78'
+                   'cca9040d6c079f1f7626fbf28f32968994834821d29cf3d3d75089e7f3368815')
+sha256sums_aarch64=('1469a8a49d90adf8143c5afdf4f2a408daa2c0218aec5b8d00cebad1e0ed535f'
+                    '228674272b2750c057e3ab8668a52cdcb64f543943b5bd0b2fad6905f120feed')
+
+package() {
+	install -dm755 "${pkgdir}/usr/lib/${_pkgname}/"
+	find . -mindepth 1 -maxdepth 1 -type f ! -name "*.zip" ! -name "LICENSE*" -exec cp -r --no-preserve=ownership --preserve=mode -t "${pkgdir}/usr/lib/${_pkgname}/." {} +
+
+	for _folder in 'locales' 'resources'; do
+		cp -r --no-preserve=ownership --preserve=mode "${_folder}/" "${pkgdir}/usr/lib/${_pkgname}/${_folder}/"
+	done
+
+	chmod u+s "${pkgdir}/usr/lib/${_pkgname}/chrome-sandbox"
+
+	install -dm755 "${pkgdir}/usr/bin"
+	ln -nfs "/usr/lib/${_pkgname}/${_projectname}" "${pkgdir}/usr/bin/${_pkgname}"
+
+	for _license in 'LICENSE' 'LICENSES.chromium.html'; do
+		install -Dm644 "${_license}" "${pkgdir}/usr/share/licenses/${pkgname}/${_license}"
+	done
+}