initial commit

1 files changed, 60 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..859477b0c14b
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,60 @@
+# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
+pkgname=emojimart
+pkgver=0.1.1
+pkgrel=1
+pkgdesc="Modern emoji picker popup for desktop"
+arch=('x86_64')
+url="https://github.com/vemonet/EmojiMart"
+license=('MIT')
+depends=('gtk3' 'webkit2gtk')
+makedepends=('cargo' 'setconf' 'yarn')
+optdepends=('xdotool: automatically paste to your currently focused app (X11 only)')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
+sha256sums=('f20f643d621ddc2cd24b5e678f4925f17391239f389865720d0114c53304508a')
+
+prepare() {
+  cd "EmojiMart-$pkgver"
+  export YARN_CACHE_FOLDER="$srcdir/yarn-cache"
+  export CARGO_HOME="$srcdir/cargo-home"
+  export RUSTUP_TOOLCHAIN=stable
+
+  # yarn.lock is used
+  rm -f package-lock.json
+
+  yarn install
+
+  # Desktop file
+  setconf public/EmojiMart.desktop Exec "$pkgname"
+  setconf public/EmojiMart.desktop Icon "$pkgname"
+
+  cd src-tauri
+  cargo fetch --target "$CARCH-unknown-linux-gnu"
+
+  # Don't bundle AppImage
+  sed -i 's/"targets": "all",/"targets": "deb",/g' tauri.conf.json
+}
+
+build() {
+  cd "EmojiMart-$pkgver"
+  export YARN_CACHE_FOLDER="$srcdir/yarn-cache"
+  export CARGO_HOME="$srcdir/cargo-home"
+  export RUSTUP_TOOLCHAIN=stable
+  yarn build
+  yarn tauri build
+}
+
+package() {
+  cd "EmojiMart-$pkgver"
+  install -Dm755 src-tauri/target/release/emoji-mart "$pkgdir/usr/bin/$pkgname"
+
+  for i in 32x32 128x128 128x128@2x; do
+    install -Dm644 src-tauri/icons/${i}.png \
+      "$pkgdir/usr/share/icons/hicolor/${i}/apps/$pkgname.png"
+  done
+
+  install -Dm644 src-tauri/icons/icon.png \
+    "$pkgdir/usr/share/icons/hicolor/512x512/apps/$pkgname.png"
+  install -Dm644 public/EmojiMart.desktop \
+    "$pkgdir/usr/share/applications/$pkgname.desktop"
+  install -Dm644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}