Initial commit

1 files changed, 46 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..904ab6e9eeba
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: nroi <nroi@mailbox.org>
+pkgname=flexo-git
+pkgrel=1
+pkgver=0.1.0.r61.gf75e159
+pkgdesc="A central pacman cache"
+# TODO we haven't tested yet if this package can be built on ARM architectures.
+arch=('x86_64' 'armv6h' 'armv7h' 'aarch64')
+url='https://github.com/nroi/flexo'
+license=('MIT')
+provides=("flexo")
+makedepends=('cargo' 'git')
+depends=('curl')
+backup=('etc/flexo/flexo.toml')
+install="${pkgname%-git}.install"
+source=('git+https://github.com/nroi/flexo.git'
+        'sysuser.conf'
+        'flexo.install'
+        'flexo.service'
+        'flexo.toml'
+)
+sha256sums=('SKIP'
+            'b6a618c66d3ffb9ad119b0497d2181cdd382ec870cc768606debed40716c1f4e'
+            '662e8c6c4d024ec035c2c02d9298a8cb6062cfb30d02bfaecf17a9d3d9b35167'
+            '0ba13ff1d92b51433635e1fbf5f1017e3e06b3e408be663acb1fbf65f344a3ad'
+            'b1ec4badc2088ed46230dad406d44130089ff00a1e98ff5d178d6f9e1eb0a98d'
+)
+
+build() {
+  cd "${pkgname%-git}/${pkgname%-git}"
+  # To avoid the warning "Package contains reference to $srcdir"
+  export CARGO_BUILD_RUSTFLAGS="--remap-path-prefix $HOME=HOME"
+  cargo build --release
+}
+
+pkgver() {
+  cd "${srcdir}/${pkgname%-git}"
+  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+package() {
+  install -Dm644 "${pkgname%-git}/LICENSE" "$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
+  install -Dm644 "${srcdir}/flexo.service" "${pkgdir}/usr/lib/systemd/system/flexo.service"
+  install -Dm644 "${srcdir}/sysuser.conf" "${pkgdir}/usr/lib/sysusers.d/flexo.conf"
+  install -Dm644 "${srcdir}/flexo.toml" "$pkgdir/etc/flexo/flexo.toml"
+  install -Dm755 "${pkgname%-git}/${pkgname%-git}/target/release/flexo" "$pkgdir/usr/bin/flexo"
+}