Various changes

- fix license
- update depends
- add optdepends for gif2flif and apng2flif tools
- remove apt-get references from gif2flif and apng2flif tools
- add patch for using build flags
- package(): use make install targets
- cosmetic changes

1 files changed, 49 insertions, 30 deletions

diff --git a/PKGBUILD b/PKGBUILD
index 614a314a1c0d..efde8d0a1e86 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,40 +1,59 @@
-# Maintainer: John Jenkins <twodopeshaggy@gmail.com>
+# Maintainer : Daniel Bermond < yahoo-com: danielbermond >
+# Contributor: John Jenkins <twodopeshaggy@gmail.com>
 
 pkgname=flif
-_pkgname=FLIF
+_srcname=FLIF
 pkgver=0.3
-pkgrel=1
-pkgdesc="Free Lossless Image Format"
-arch=("i686" "x86_64")
-url="https://github.com/FLIF-hub/FLIF"
-license=('GPL3')
+pkgrel=2
+pkgdesc='Free Lossless Image Format'
+arch=('i686' 'x86_64')
+url='https://github.com/FLIF-hub/FLIF/'
+license=('LGPL3' 'APACHE')
+depends=('gcc-libs' 'libpng' 'sdl2')
+optdepends=(
+    # official repositories:
+        'imagemagick: for gif2flif tool'
+    # AUR:
+        'apng-utils: for apng2flif tool'
+)
 conflicts=('flif-git')
-depends=('zlib' 'libpng' 'sdl2')
-source=("https://github.com/FLIF-hub/FLIF/archive/v${pkgver//_/-}.tar.gz")
-md5sums=('0bc4d0a71d67b2c6e040e2d5a93dcd2d')
+source=("${pkgname}-${pkgver}.tar.gz"::"https://github.com/FLIF-hub/FLIF/archive/v${pkgver}.tar.gz"
+        'flif-use-build-flags.patch')
+sha256sums=('aa02a62974d78f8109cff21ecb6d805f1d23b05b2db7189cfdf1f0d97ff89498'
+            'd8cdb93f4f1e63487d65d23c1c96bf79acff1277532cbcfd88ca05932655d871')
+
+prepare() {
+    cd "${_srcname}-${pkgver}"
+    
+    # use build flags
+    patch -Np1 -i "${srcdir}/flif-use-build-flags.patch"
+    
+    # remove apt-get references from installed tools
+    cd tools
+    sed -i '/apt-get/d' gif2flif apng2flif
+}
 
 build() {
-  cd "$srcdir/${_pkgname}-${pkgver//_/-}/src"
-  make all
-  make decoder
-  make viewflif
+    cd "${_srcname}-${pkgver}/src"
+    
+    local _target
+    
+    for _target in all decoder viewflif
+    do
+        msg2 "Building target '${_target}'..."
+        make "$_target"
+    done
+    
 }
 
 package() {
-  cd "$srcdir/${_pkgname}-${pkgver//_/-}/src"
-  install -dm755 "${pkgdir}/usr/bin"
-  install -dm755 "${pkgdir}/usr/lib/"
-  install -dm755 "${pkgdir}/usr/share/man/man1/"
-  install -dm755 "${pkgdir}/usr/include/${_pkgname}"
-  install -m755 flif viewflif dflif "${pkgdir}/usr/bin"
-  install -m755 libflif_dec.so "${pkgdir}/usr/lib/"
-  install -m755 libflif_dec.so.0 "${pkgdir}/usr/lib/"
-  install -m755 libflif.so "${pkgdir}/usr/lib/"
-  install -m755 libflif.so.0 "${pkgdir}/usr/lib/"
-  install -m 644 library/*.h "${pkgdir}/usr/include/${_pkgname}"
-  install -m 644 ../doc/flif.1 "${pkgdir}/usr/share/man/man1"
-  install -m 755 ../tools/gif2flif "${pkgdir}/usr/bin"
-  install -m 755 ../tools/apng2flif "${pkgdir}/usr/bin"
-  cd "$srcdir/${_pkgname}-${pkgver//_/-}"
-  install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
+    cd "${_srcname}-${pkgver}/src"
+    
+    local _target
+    
+    for _target in install{,-dev,-decoder,-viewflif}
+    do
+        msg2 "Installing target '${_target}'..."
+        make PREFIX="${pkgdir}/usr" "$_target"
+    done
 }