initial commit - no official release, so pkgver is 0.0.0+258.3921ae69e8

Signed-off-by: Eric Engestrom <eric.engestrom@intel.com>

1 files changed, 42 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..4a57c18a9378
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: Eric Engestrom <aur [at] engestrom [dot] ch>
+
+pkgname=fossilize
+pkgver=0.0.0+258.3921ae69e8
+pkgrel=1
+pkgdesc="Library and Vulkan layer for serializing various persistent Vulkan objects which typically end up in hashmaps"
+arch=(x86_64)
+url="https://github.com/ValveSoftware/Fossilize"
+license=(MIT)
+depends=()
+makedepends=(rapidjson)
+source=("git+$url")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd Fossilize
+  printf '0.0.0+%d.%s' \
+    $(git rev-list --count HEAD) \
+    $(git rev-parse HEAD | head -c10)
+}
+
+build() {
+  cd Fossilize
+  git submodule update --init --recursive
+  mkdir -p build
+  cd build
+  cmake .. \
+    -DFOSSILIZE_RAPIDJSON_INCLUDE_PATH=/usr/include/rapidjson/ \
+    -DCMAKE_BUILD_TYPE=Release
+  make
+}
+
+package() {
+  cd Fossilize/build
+
+  install -dm755 "$pkgdir/usr/bin"
+  install -m755 cli/fossilize-* "$pkgdir/usr/bin"
+
+  install -dm755 "$pkgdir/usr/lib" "$pkgdir/usr/share/vulkan/explicit_layer.d"
+  install -m755 layer/libVkLayer_fossilize.so "$pkgdir/usr/lib"
+  install -m755 layer/VkLayer_fossilize.json "$pkgdir/usr/share/vulkan/explicit_layer.d"
+}