Split out HTML manual

1 files changed, 23 insertions, 14 deletions

diff --git a/PKGBUILD b/PKGBUILD
index 966cfba59eab..ed37b69b986d 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,45 +1,54 @@
 # Maintainer: Michael Straube <straubem@gmx.de>
 # Contributor: Robert Knauer <robert@privatdemail.net>
 
-pkgname=freedoko
+pkgbase=freedoko
+pkgname=('freedoko' 'freedoko-docs')
 pkgver=0.7.16
-pkgrel=1
-pkgdesc="Free version of the german card game Doppelkopf"
+pkgrel=2
+pkgdesc="Free implementation of the card game Doppelkopf"
 arch=('i686' 'x86_64')
 url="http://free-doko.sourceforge.net/en/FreeDoko.html"
 license=('GPL')
 depends=('gtkmm3' 'gnet' 'freealut')
 makedepends=('asciidoc' 'texlive-latexextra' 'w3m' 'dos2unix')
 source=("https://downloads.sourceforge.net/free-doko/FreeDoko_$pkgver.src.zip"
-        "freedoko-$pkgver-archlinux.patch")
+        "freedoko-archlinux.patch")
 sha256sums=('6fdcee22b3e9a76d44d8c3a582d068452290ec4c24f8f2f9e4498adf4daf40af'
-            '329b77525f18d3c1837b78d1b4bd1c8446afb9cd530458345e23a39423f9598b')
+            'af53095c0de32ee01cec8eeb8e34b722b206de5b5e13bf8553bf2cf91ef91bab')
 
 prepare() {
   cd FreeDoko_$pkgver
 
-  # patch Makefiles
-  patch -p1 -i ../freedoko-$pkgver-archlinux.patch
+  patch -p1 -i ../freedoko-archlinux.patch
+  find manual -type f -exec chmod 644 {} \;
 }
 
 build() {
   cd FreeDoko_$pkgver
 
+  CXXFLAGS+=' -Wno-deprecated'
+
   make compile
   make documentation
 }
 
-package() {
+package_freedoko() {
+  optdepends=('freedoko-docs: HTML manual')
+
   cd FreeDoko_$pkgver
 
   make DESTDIR="$pkgdir" install
+  install -Dm644 bin/FreeDoko.desktop "$pkgdir"/usr/share/applications/freedoko.desktop
+  rm "$pkgdir"/usr/share/doc/freedoko/{de/Windows,de/SuSE,en/Windows,hpux*}
+}
 
-  install -Dm644 bin/FreeDoko.desktop \
-    "$pkgdir"/usr/share/applications/freedoko.desktop
+package_freedoko-docs() {
+  pkgdesc="HTML manual for FreeDoko"
+  arch=('any')
+  depends=()
 
-  tar -c --exclude={*.sh,Makefile} manual |
-    tar -x -C "$pkgdir"/usr/share/doc/freedoko
+  cd FreeDoko_$pkgver
 
-  find "$pkgdir"/usr/share/doc/freedoko/manual -type f -exec chmod 644 {} \;
-  rm "$pkgdir"/usr/share/doc/freedoko/{de/Windows,de/SuSE,en/Windows,hpux*}
+  install -d "$pkgdir"/usr/share/doc/freedoko
+  tar -c --exclude={*.sh,Makefile} manual | tar -x -C "$pkgdir"/usr/share/doc/freedoko
 }