summarylogtreecommitdiffstats
path: root/PKGBUILD
diff options
context:
space:
mode:
authortdy2017-01-19 23:13:27 -0600
committertdy2017-01-19 23:13:27 -0600
commitc05d0b3d45e55493cc66d4819d52b78dae59e97a (patch)
tree0b1d762b5595643a3bebbc1db7aa00fe4c4ab9a5 /PKGBUILD
downloadaur-frinika.tar.gz
Initial commit
Diffstat (limited to 'PKGBUILD')
-rw-r--r--PKGBUILD49
1 files changed, 49 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..10bdf5be4d32
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: archlinux.info:tdy
+
+pkgname=frinika
+pkgver=0.8.1
+_pkgdate=-2016-11-21
+pkgrel=1
+pkgdesc="A free music workstation (sequencer, software synth, audio recording, etc.)"
+arch=(i686 x86_64)
+url=http://www.frinika.com
+license=(GPL LGPL BSD custom)
+depends=(java-runtime jack)
+source=(https://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver$_pkgdate.zip
+ $pkgname.desktop
+ $pkgname.sh)
+noextract=($pkgname-$pkgver$_pkgdate.zip)
+sha256sums=(379f11a29a042b0963d2070ea0100750a5357a5d45bf1117f1faa70e86150bbb
+ 6dff025123dddd899a3f424a675444b75950a45bebaa217ff6b3cfc7a1232ba7
+ ff34c2db17dbc98b114721ff8c45669c59874344b4705094ef9b411c3f2c7e68)
+
+package() {
+ bsdtar -xf $pkgname-$pkgver$_pkgdate.zip -C "$pkgdir" \
+ -s ":^$pkgname-$pkgver$_pkgdate:usr/share/java/$pkgname:"
+ bsdtar -xf "$pkgdir"/usr/share/java/$pkgname/$pkgname.jar -C "$pkgdir" \
+ -s ":^icons:usr/share/pixmaps:" icons/$pkgname.png
+
+ # launchers
+ install -Dm755 $pkgname.sh "$pkgdir"/usr/bin/$pkgname
+ install -Dm644 $pkgname.desktop "$pkgdir"/usr/share/applications/$pkgname.desktop
+
+ # libjack
+ install -dm755 "$pkgdir"/usr/lib
+ ln -sf libjack.so "$pkgdir"/usr/lib/libjack-0.100.0.so.0
+
+ # docs
+ cd "$pkgdir"/usr/share/java/$pkgname
+ install -Dm644 README.TXT "$pkgdir"/usr/share/doc/$pkgname/README
+ install -Dm644 lib/RasmusDSP_LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/RasmusDSP.txt
+ install -Dm644 lib/flexdock_LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/flexdock.txt
+ install -Dm644 lib/looks_LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/looks.txt
+ install -Dm644 lib/toot_LICENSE.txt "$pkgdir"/usr/share/licenses/$pkgname/toot.txt
+
+ # cleanup
+ msg2 "Cleaning up..."
+ [[ $CARCH == x86_64 ]] && rm -rf lib/i386 || rm -rf lib/amd64
+ rm -f LICENSE.md README.TXT lib/*.txt
+ find . -type f -exec chmod 644 '{}' \;
+ find . -type d -exec chmod 755 '{}' \;
+ chown -R root:root .
+}