Initial commit

1 files changed, 42 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..d8998c9dd407
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: Pierre-Marie de Rodat <pmderodat on #ada at freenode.net>
+
+pkgname=gnatcoll-core-git
+pkgver=r2835.ed921e27
+pkgrel=1
+
+pkgdesc='GNAT Components Collection - Core packages'
+url='https://github.com/AdaCore/gnatcoll-core/'
+arch=('i686' 'x86_64')
+license=('GPL')
+
+depends=('gcc-ada' 'libgpr')
+makedepends=('git' 'gprbuild')
+
+provides=('gnatcoll-core')
+conflicts=('gnatcoll-core')
+
+source=('git+https://github.com/AdaCore/gnatcoll-core.git')
+sha1sums=('SKIP')
+
+pkgver() {
+    cd "$srcdir/${pkgname%-git}"
+    printf "r%s.%s" \
+        "$(git rev-list --count HEAD)" \
+        "$(git rev-parse --short HEAD)"
+}
+
+build()
+{
+    cd "$srcdir/${pkgname%-git}"
+    make setup BUILD=PROD prefix=/usr
+    make PROCESSORS="$(nproc)" GPRBUILD_OPTIONS=-R
+}
+
+package()
+{
+    cd "$srcdir/${pkgname%-git}"
+
+    # Make one install at a time to avoid GPRinstall reading/writing to
+    # the same installed project files at the same time.
+    make prefix="$pkgdir/usr" install -j1
+}