Initial import

1 files changed, 38 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..faa30de154c5
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: Igor Dyatlov <dyatlov.igor@protonmail.com>
+
+pkgname=gnome-shell-extension-panel-corners-git
+_pkgname=panel-corners
+pkgver=r14.344c1a8
+pkgrel=1
+pkgdesc="A gnome-shell extension to keep the old topbar corners, which were removed for GNOME 42"
+arch=('any')
+url="https://github.com/aunetx/panel-corners"
+license=('GPL3')
+depends=('gnome-shell')
+makedepends=('git' 'zip')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=(git+$url.git)
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$_pkgname"
+  ( set -o pipefail
+    git describe --long 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+  )
+}
+
+build() {
+  cd "$_pkgname"
+
+  make pkg
+}
+
+package() {
+  cd "$_pkgname"
+
+  local uuid=$(grep -Po '(?<="uuid": ")[^"]*' metadata.json)
+  install -d "$pkgdir/usr/share/gnome-shell/extensions/${uuid}"
+  bsdtar -xvf pkg/${uuid}.zip -C "$pkgdir/usr/share/gnome-shell/extensions/${uuid}"
+}