Initial

1 files changed, 36 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..21e7e60c3e33
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: surefire@cryptomile.net
+
+pkgname=gnome-shell-extension-shelltile-git
+pkgver=0+19+g569ddba
+pkgrel=1
+pkgdesc='A tiling window extension for GNOME Shell'
+arch=('any')
+url='https://extensions.gnome.org/extension/657/shelltile/'
+license=('GPLv2')
+depends=('gnome-shell')
+makedepends=('git')
+conflicts=('gnome-shell-extension-shelltile')
+provides=('gnome-shell-extension-shelltile')
+groups=('gnome-shell-extensions')
+source=('git+https://github.com/emasab/shelltile.git')
+sha256sums=('SKIP')
+
+pkgver() {
+	cd shelltile
+
+	printf '0+%s+g%s' $(git rev-list --count HEAD) $(git rev-parse --short HEAD)
+}
+
+package() {
+	cd shelltile
+
+	local uuid='ShellTile@emasab.it'
+	local destdir="$pkgdir/usr/share/gnome-shell/extensions/$uuid"
+
+	install -Dm644 -t "$pkgdir/usr/share/glib-2.0/schemas"         schemas/*.xml
+	install -Dm644 -t "$pkgdir/usr/share/licenses/${pkgname%-git}" LICENSE
+
+	install -Dm644 -t "$destdir" *.js *.json *.css
+	find locale -type f -name '*.mo' \
+		-exec cp --parents -dpt "$destdir" {} +
+}