No one is perfect – that’s why pencils have erasers. -- Wolfgang Riebe

1 files changed, 65 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..a144dd5325a9
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,65 @@
+# Maintainer: Fabian Bornschein <fabiscafe-cat-mailbox-dog-org>
+# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
+# Contributor: Ionut Biru <ibiru@archlinux.org>
+# Contributor: Flamelab <panosfilip@gmail.com
+
+pkgname=gnome-shell-oldstable
+pkgver=3.38.4
+pkgrel=2
+epoch=1
+pkgdesc="Next generation desktop shell"
+url="https://wiki.gnome.org/Projects/GnomeShell"
+conflicts=("gnome-shell")
+provides=("gnome-shell=$pkgver")
+replaces=("gnome-shell")
+arch=(x86_64)
+license=(GPL)
+depends=(accountsservice gcr gjs gnome-bluetooth upower gnome-session gtk4
+         gnome-settings-daemon-oldstable gnome-themes-extra gsettings-desktop-schemas-oldstable
+         libcanberra-pulse libgdm libsecret mutter-oldstable nm-connection-editor unzip
+         gstreamer libibus gnome-autoar gnome-disk-utility gst-plugin-pipewire)
+makedepends=(gtk-doc gnome-control-center evolution-data-server
+             gobject-introspection git meson sassc asciidoc bash-completion)
+checkdepends=(xorg-server-xvfb)
+optdepends=('gnome-control-center: System settings'
+            'evolution-data-server: Evolution calendar integration')
+groups=(gnome-oldstable)
+install=gnome-shell.install
+_commit=d91b41ade09ea9960678416ab919ececf12ec8d1  # tag/3.38.4
+source=("git+https://gitlab.gnome.org/GNOME/gnome-shell.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd gnome-shell
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd gnome-shell
+
+  git submodule init
+  git submodule set-url subprojects/gvc "$srcdir/libgnome-volume-control"
+  git submodule update
+}
+
+build() {
+  arch-meson gnome-shell build -D gtk_doc=true
+  meson compile -C build
+}
+
+check() (
+  # Check might fail without clean build env. Continue building in any case.
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  export XDG_RUNTIME_DIR
+
+  dbus-run-session xvfb-run \
+    -s '-screen 0 1920x1080x24 -nolisten local +iglx -noreset' \
+  meson test -C build --print-errorlogs || true
+)
+
+package() {
+  depends+=(libmutter-7.so)
+  DESTDIR="$pkgdir" meson install -C build
+}