feat: add package google-cloud-sdk-app-engine-python-extras

1 files changed, 38 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..db5b76f5c534
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: Benjamin Denhartog <ben@sudoforge.com>
+# Contributor: Tim Brown <stimut@gmail.com>
+
+pkgname=google-cloud-sdk-app-engine-python-extras
+pkgver=290.0.1
+pkgrel=1
+pkgdesc="A google-cloud-sdk component that provides extra libraries for the Python runtime for AppEngine."
+url="https://cloud.google.com/sdk/"
+license=("Apache")
+arch=('x86_64')
+options=('!strip')
+depends=(
+  "google-cloud-sdk=${pkgver}"
+  "google-cloud-sdk-app-engine-python=${pkgver}"
+)
+source=(
+  "https://dl.google.com/dl/cloudsdk/release/downloads/for_packagers/linux/${pkgname}_${pkgver}.orig.tar.gz"
+)
+sha256sums=('b6a16aa3186539ee813bec73dc15d912e553ec5eb8365ddb403a4e67dbd914b8')
+
+package() {
+  mkdir "${pkgdir}/opt"
+
+  # Install the component manifest file
+  install -D -m 0644 \
+    "${srcdir}/google-cloud-sdk/.install/app-engine-python.manifest" \
+    "${pkgdir}/opt/google-cloud-sdk/.install/app-engine-python.manifest"
+
+  # Install the component metadata snapshot file
+  install -D -m 0644 \
+    "${srcdir}/google-cloud-sdk/.install/app-engine-python.snapshot.json" \
+    "${pkgdir}/opt/google-cloud-sdk/.install/app-engine-python.snapshot.json"
+
+  # Install the component files
+  cp -R \
+    "${srcdir}/google-cloud-sdk/platform/google_appengine" \
+    "${pkgdir}/opt/google-cloud-sdk/platform/google_appengine"
+}