Add gtk-theme-elementary-git

1 files changed, 31 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..e36252aca36b
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,31 @@
+# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
+
+pkgname=gtk-theme-elementary-git
+pkgver=r1020.bf0893a
+pkgrel=1
+pkgdesc='elementary GTK theme'
+arch=('any')
+url='https://github.com/elementary/stylesheet'
+license=('GPL3')
+groups=('pantheon-unstable')
+optdepends=('gtk-engine-murrine: GTK2 theme')
+makedepends=('git')
+provides=('gtk-theme-elementary')
+conflicts=('gtk-theme-elementary')
+replaces=('gtk-theme-elementary-bzr')
+source=('gtk-theme-elementary::git+https://github.com/elementary/stylesheet.git')
+sha256sums=('SKIP')
+
+pkgver() {
+  cd gtk-theme-elementary
+
+  echo "r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
+}
+
+package() {
+  install -dm 755 "${pkgdir}"/usr/share/themes
+  cp -dr --no-preserve='ownership' gtk-theme-elementary "${pkgdir}"/usr/share/themes/elementary
+  rm -rf "${pkgdir}"/usr/share/themes/elementary/{.git,.gitignore,.stylelintrc.json,.travis.yml}
+}
+
+# vim: ts=2 sw=2 et: