gtk3-donnatella: Import gtk3 from ABS

Signed-off-by: Olivier Brunel <jjk@jjacky.com>

1 files changed, 45 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..1cefe9bd8931
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,45 @@
+# $Id$
+# Maintainer: Ionut Biru <ibiru@archlinux.org>
+# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
+
+pkgname=gtk3
+pkgver=3.10.7
+pkgrel=1
+pkgdesc="GObject-based multi-platform GUI toolkit (v3)"
+arch=(i686 x86_64)
+url="http://www.gtk.org/"
+install=gtk3.install
+depends=(atk cairo gtk-update-icon-cache libcups libxcursor libxinerama libxrandr libxi
+         libxcomposite libxdamage pango shared-mime-info colord at-spi2-atk wayland libxkbcommon)
+makedepends=(gobject-introspection)
+optdepends=('gnome-themes-standard: Default widget theme'
+            'gnome-icon-theme: Default icon theme')
+license=(LGPL)
+source=(http://ftp.gnome.org/pub/gnome/sources/gtk+/${pkgver%.*}/gtk+-$pkgver.tar.xz
+        settings.ini)
+sha256sums=('b7e9de15385031cff43897e7e59f6692eaabf500f36eef80e6b9d6486ad49427'
+            '14369dfd1d325c393e17c105d5d5cc5501663277bd4047ea04a50abb3cfbd119')
+
+build() {
+    cd "gtk+-$pkgver"
+
+    CXX=/bin/false ./configure --prefix=/usr \
+        --sysconfdir=/etc \
+        --localstatedir=/var \
+        --enable-gtk2-dependency \
+        --disable-schemas-compile \
+        --enable-x11-backend \
+        --enable-broadway-backend \
+        --enable-wayland-backend
+
+    #https://bugzilla.gnome.org/show_bug.cgi?id=655517
+    sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+    make
+}
+
+package() {
+    cd "gtk+-$pkgver"
+    make DESTDIR="$pkgdir" install
+    install -Dm644 ../settings.ini "$pkgdir/usr/share/gtk-3.0/settings.ini"
+}