Add gzdoom1 package

1 files changed, 78 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..aa9e00bbb830
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,78 @@
+# Maintainer: Jan Cholasta <grubber at grubber cz>
+
+pkgname=gzdoom1
+pkgver=1.8.07
+pkgrel=1
+pkgdesc="Doom source port based on ZDoom with an OpenGL renderer (legacy version)."
+arch=('i686' 'x86_64')
+url="http://www.osnanet.de/c.oelckers/gzdoom/"
+license=('custom')
+depends=('fluidsynth' 'fmodex4.26.36' 'glew' 'gtk2' 'gxmessage' 'sdl')
+makedepends=('nasm' 'cmake' 'imagemagick' 'mesa')
+optdepends=('blasphemer: Blasphemer (free Heretic) game data'
+            'chexquest3-wad: Chex Quest 3 game data'
+            'doom1-wad: Doom shareware game data'
+            'freedoom: FreeDoom game data'
+            'hacx-wad: HacX game data'
+            'harmony-wad: Harmony game data'
+            'heretic1-wad: Heretic shareware game data'
+            'hexen1-wad: Hexen demo game data'
+            'strife0-wad: Strife shareware game data'
+            'urbanbrawl-wad: Urban Brawl: Action Doom 2 game data')
+provides=('gzdoom')
+conflicts=('gzdoom')
+source=(https://github.com/coelckers/gzdoom/archive/g${pkgver}.tar.gz
+        config-update-fix.patch \
+        doom-share-dir.patch \
+        stack-noexec.patch \
+        gzdoom.desktop)
+md5sums=('a73d1e00f0e884985cb373d315e276c8'
+         'eed301389f533effbd127681a3ddc2c5'
+         '3ee3d6bb1f777445438bc40ae81a95df'
+         '4778bb22190c445a4ed764c64432de12'
+         '3f5920d839086c9ad04ed1338c3fb546')
+
+_fmodver=4.26.36
+_libdir=/usr/lib/gzdoom
+_sharedir=/usr/share/games/gzdoom
+
+prepare() {
+  cd gzdoom-g$pkgver
+
+  patch -p1 <"$srcdir/config-update-fix.patch"
+  patch -p1 <"$srcdir/doom-share-dir.patch"
+  patch -p1 <"$srcdir/stack-noexec.patch"
+
+  sed -i "s|setPluginPath(progdir)|setPluginPath(\"$_libdir\")|" src/sound/fmodsound.cpp
+}
+
+build() {
+  cd gzdoom-g$pkgver
+
+  cmake -DFMOD_INCLUDE_DIR=/usr/include/fmodex-$_fmodver \
+        -DFMOD_LIBRARY=/usr/lib/libfmodex-$_fmodver.so \
+        -DCMAKE_C_FLAGS="$CFLAGS -DSHARE_DIR=\\\"$_sharedir\\\"" \
+        -DCMAKE_CXX_FLAGS="$CXXFLAGS -DSHARE_DIR=\\\"$_sharedir\\\"" \
+        .
+  make
+
+  convert "src/win32/icon1.ico[2]" gzdoom.png
+}
+
+package() {
+  cd gzdoom-g$pkgver
+
+  install -Dm755 gzdoom "$pkgdir/usr/bin/gzdoom"
+  install -Dm755 liboutput_sdl.so "$pkgdir/$_libdir/liboutput_sdl.so"
+  install -Dm644 gzdoom.pk3 "$pkgdir/$_sharedir/gzdoom.pk3"
+  install -Dm644 brightmaps.pk3 "$pkgdir/$_sharedir/brightmaps.pk3"
+  install -Dm644 lights.pk3 "$pkgdir/$_sharedir/lights.pk3"
+  ln -s /usr/share/doom/doom.wad "$pkgdir/$_sharedir/freedoomu.wad"
+  ln -s /usr/share/doom/doom2.wad "$pkgdir/$_sharedir/freedoom.wad"
+  ln -s /usr/share/doom/hexen.wad "$pkgdir/$_sharedir/hexendemo.wad"
+
+  install -Dm644 gzdoom.png "$pkgdir/usr/share/pixmaps/gzdoom.png"
+  install -Dm644 "$srcdir/gzdoom.desktop" "$pkgdir/usr/share/applications/gzdoom.desktop"
+  install -Dm644 docs/BUILDLIC.TXT "$pkgdir/usr/share/licenses/$pkgname/BUILDLIC.TXT"
+  install -Dm644 docs/doomlic.txt "$pkgdir/usr/share/licenses/$pkgname/DOOMLIC.TXT"
+}