initial commit

1 files changed, 39 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..08f179c715d0
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,39 @@
+
+# Maintainer: Solomon Choina <shlomochoina@gmail.com>
+pkgname=haskell-bytestring-to-vector
+_hkgname=bytestring-to-vector
+pkgver=0.3.0.1
+pkgrel=1
+pkgdesc="Convert between ByteString and Vector.Storable without copying"
+url=https://hackage.haskell.org/package/bytestring-to-vector
+license=('BSD3')
+arch=('i686' 'x86_64')
+depends=('ghc-libs' 'haskell-base' 'haskell-bytestring' 'haskell-vector')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha256sums=('ccfb5bdccd88a5be488acb291a5863d9026e109d2178e58d87948b43b519284a')
+
+
+build() {
+	cd "${srcdir}/${_hkgname}-${pkgver}"
+	runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgname}" --datasubdir="$pkgname" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build
+    runhaskell Setup haddock
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd ${_hkgname}-${pkgver}
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    install -d -m755 "${pkgdir}/usr/share/doc/ghc/html/libraries"
+    ln -s /usr/share/doc/${pkgname}/html "${pkgdir}/usr/share/doc/ghc/html/libraries/${_hkgname}"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/LICENSE"
+}