update to 0.9.1

1 files changed, 59 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..7e1fd59e5d3f
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,59 @@
+# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
+pkgname=horen
+pkgver=0.9.1
+_electronversion=28
+pkgrel=1
+pkgdesc="A music player by Electron"
+arch=('any')
+url="https://github.com/horenjs/horen"
+license=('MIT')
+conflicts=("${pkgname}")
+depends=(
+    "electron${_electronversion}"
+)
+makedepends=(
+    'gendesk'
+    'git'
+    'npm'
+    'pnpm'
+    'nodejs'
+    'imagemagick'
+)
+source=(
+    "${pkgname}.git::git+${url}.git#tag=beta"
+    "${pkgname}.sh"
+)
+sha256sums=('SKIP'
+            '0fb7b939a071f4a08476bdd5aa143d2aa8cd335c83309f9919be16cd5c3e2014')
+build() {
+    sed -e "s|@electronversion@|${_electronversion}|" \
+        -e "s|@appname@|${pkgname}|g" \
+        -e "s|@runname@|app|g" \
+        -i "${srcdir}/${pkgname}.sh"
+    gendesk -q -f -n --categories="AudioVideo" --name="${pkgname}" --exec="${pkgname} %U"
+    cd "${srcdir}/${pkgname}.git"
+    export npm_config_build_from_source=true
+    export ELECTRON_SKIP_BINARY_DOWNLOAD=1
+    export SYSTEM_ELECTRON_VERSION="$(electron${_electronversion} -v | sed 's/v//g')"
+    export npm_config_target="${SYSTEM_ELECTRON_VERSION}"
+    export ELECTRONVERSION="${_electronversion}"
+    export npm_config_disturl=https://electronjs.org/headers
+    HOME="${srcdir}/.electron-gyp"
+    pnpm config set store-dir "${srcdir}/.pnpm_store"
+    pnpm config set cache-dir "${srcdir}/.pnpm_cache"
+    pnpm config set link-workspace-packages true
+    convert preview/${pkgname}.ico preview/${pkgname}.png
+    sed "34,37d;s|${pkgname}.ico|${pkgname}.png|g" -i forge.config.js
+    sed "s|process.env.APPDATA|'/home/${USER}'|g" -i app/main/src/constant.ts
+    pnpm install
+    pnpm run build
+    pnpm run make
+}
+package() {
+    install -Dm755 "${srcdir}/${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"
+    install -Dm755 -d "${pkgdir}/usr/lib/${pkgname}"
+    cp -r "${srcdir}/${pkgname}.git/out/${pkgname}-linux-"*/resources/app "${pkgdir}/usr/lib/${pkgname}"
+    install -Dm644 "${srcdir}/${pkgname}.git/preview/${pkgname}.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
+    install -Dm644 "${srcdir}/${pkgname}.desktop" -t "${pkgdir}/usr/share/applications"
+    install -Dm644 "${srcdir}/${pkgname}.git/out/${pkgname}-linux-"*/LICENSE* -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
\ No newline at end of file