Initial commit

1 files changed, 47 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..9150299d5547
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: Malte Rabenseifner <mail@malte-rabenseifner.de>
+
+pkgname=icingaweb2-git
+_pkgname=icingaweb2
+pkgver=r7176.9b14fff
+pkgrel=1
+pkgdesc="Icinga Web 2 Interface"
+license=('GPL')
+arch=('any')
+depends=('php')
+makedepends=('git')
+optdepends=('php-gd: export data to PDF'
+            'php-intl: support for internationalization'
+            'php-ldap: for LDAP authentication'
+            'php-pgsql: for PostgreSQL backend')
+provides=('icingaweb2')
+conflicts=('icingaweb2')
+url="http://www.icinga.org"
+source=("git+https://github.com/Icinga/icingaweb2.git")
+install='icingaweb2-git.install'
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$_pkgname"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+package() {
+  cd "$srcdir/$_pkgname"
+
+  #mkdir -p "$pkgdir/etc/webapps/icingaweb2"
+  mkdir -p "$pkgdir/etc/icingaweb2"
+  mkdir -p "$pkgdir/usr/bin"
+  mkdir -p "$pkgdir/usr/share/webapps/icingaweb2"
+  mkdir -p "$pkgdir/var/log/icingaweb2"
+
+  cp -r application doc library modules public bin "$pkgdir/usr/share/webapps/icingaweb2"
+  ln -s /usr/share/webapps/icingaweb2/bin/icingacli "$pkgdir/usr/bin/icingacli"
+
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/icingaweb2/LICENSE"
+  install -Dm644 etc/bash_completion.d/icingacli "$pkgdir/etc/bash_completion.d/icingacli"
+  cp -r etc/schema "$pkgdir/usr/share/icingaweb2"
+
+  #chmod 2770 "$pkgdir/etc/webapps/icingaweb2"
+  chmod 2770 "$pkgdir/etc/icingaweb2"
+  chmod 750 "$pkgdir/var/log/icingaweb2"
+}