update (unofficially) to 0.10.2

1 files changed, 34 insertions, 35 deletions

diff --git a/PKGBUILD b/PKGBUILD
index 63587801955e..1cc2279204f7 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,57 +1,56 @@
-# Maintainer: pigt <pay2630 at gmail dot com>
+# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
+# Contributor: pigt <pay2630 at gmail dot com>
+
 pkgname=injection
-pkgver=0.9.4
+pkgver=0.10.2
 pkgrel=1
-pkgdesc="A Python-based ASCII programming-puzzle game."
-arch=('i686' 'x86_64')
-url="https://schilcote.itch.io/injection"
+pkgdesc="Python-based ASCII programming-puzzle game"
+arch=('x86_64')
+url="https://toastengineer.itch.io/injection"
 license=('MIT')
-depends=('python-pygame' 'python-pyperclip' 'python-rsa' 'python-numpy' 'cython' 'tk' 'python-dill')
-makedepends=('unzip' 'curl' 'python-pip' )
-source=(injection.sh injection.desktop icon.png INJECTION_${pkgver}_src.zip.md5)
-md5sums=('5f21ca7a8891291e250f5296ba855324'
-         'cf419413f1dda3dcae7c665c9bb4bf46'
-         '2e6543984ecc80ddf57ed822b344e0e1'
-         '9c20daa901cc7f1230481dc45185649c')
-
-_release_url="https://schilcote.itch.io/injection/file/309125?after_download_lightbox=true"
+depends=(
+	'cython'
+	'python-dill'
+	'python-numpy'
+	'python-pygame>=1.9.4'
+	'python-pyperclip'
+	'python-rsa')
+makedepends=('python-setuptools' 'python-pip')
+source=(
+	"$pkgname-$pkgver.tar.bz2::https://gitlab.com/toastengineer/injection/-/archive/master/INJECTION-master.tar.bz2"
+	injection.sh
+	injection.desktop
+	icon.png)
+sha256sums=('4fd7c3cbf32d09283d956ca42e92f2ffb97633956288d54bf0c6f0163b9461d5'
+            '93fbcd694536f0a9928bcd4c274c5436998c8b0f6b527e7729007bd7c30dc7fe'
+            '149b1700eddf2c0aba61a7bc9756ea9a464826478e6bf94bf23ea320781991b1'
+            '1b4deae94db1a44d5ff4db9399b5038fe17d5cd45454eaa00f3f4925a49337be')
 
 prepare() {
-	#Download url always changing to prevent hotlink. So we must deal with it.
-	#url extraction code was copied from "after school"'s package.
-	_dl_url=$(curl -s -XPOST "${_release_url}" | grep -Po '"url":.*?[^\\]",' | cut -c8- | rev |cut -c3- | rev | sed 's/\\\//\//g')
-	echo "Downloading from $_dl_url"
-	if [ ! -f INJECTION_${pkgver}_src.zip ]; then
-		curl "$_dl_url" -o "INJECTION_${pkgver}_src.zip"
-	fi
-	md5sum -c INJECTION_${pkgver}_src.zip.md5
-	unzip INJECTION_${pkgver}_src.zip -d "$pkgname-$pkgver"
-	mv $pkgname-$pkgver/INJECTION\ $pkgver\ Python\ 3\ Source/* "$pkgname-$pkgver"
-
+	mv INJECTION-master "$pkgname-$pkgver"
 }
 
-_python_depends=('pymsgbox' 'pygcurse')
 build() {
 	cd "$pkgname-$pkgver"
 
 	#module that doesn't exist in repo.
-	mkdir 'custom_packages'
+	local _python_depends=('pymsgbox' 'pygcurse' 'pyconsolegraphics' 'pyerrorreport')
+	mkdir -p 'custom_packages'
 	pip install -t 'custom_packages' ${_python_depends[*]}
 	export PYTHONPATH='./custom_packages'
 
 	#Build fx
 	python setup.py build_ext
 	cp build/lib*/* .
-	rm -r build	
+	rm -r build
 }
 
 package() {
-	mkdir -p "$pkgdir/usr/lib"
-	cp -r "$pkgname-$pkgver" "$pkgdir/usr/lib/injection" #Program and assets.
-	install -D -m644 "$pkgname-$pkgver/LICENSE" "$pkgdir/usr/share/licenses/injection/LICENSE" #License.
-	install -D -m755 "injection.sh" "$pkgdir/usr/lib/injection/injection.sh" #Launch script.
-	mkdir "$pkgdir/usr/bin/"
+	install -d "$pkgdir/usr/lib" "$pkgdir/usr/bin/"
+	cp -a --no-preserve=ownership "$pkgname-$pkgver" "$pkgdir/usr/lib/injection" #Program and assets.
+	install -D -m644 "$pkgname-$pkgver/LICENSE" -t "$pkgdir/usr/share/licenses/$pkgname/"
+	install -D -m755 "injection.sh" -t "$pkgdir/usr/lib/injection/"
 	ln -s "/usr/lib/injection/injection.sh" "$pkgdir/usr/bin/injection"
-	install -D -m644 "injection.desktop" "$pkgdir/usr/share/applications/injection.desktop"
-	install -D -m644 "icon.png" "$pkgdir/usr/lib/injection/icon.png"
+	install -D -m644 "injection.desktop" -t "$pkgdir/usr/share/applications/"
+	install -D -m644 "icon.png" -t "$pkgdir/usr/lib/injection/"
 }