upload

1 files changed, 56 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..b434f7e35951
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,56 @@
+# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
+# Contributor: Chris <christopher.r.mullins g-mail>
+# Contributor: geosam <samuelmesa@linuxmail.org>
+# Contributor: Andrzej Giniewicz <gginiu@gmail.com>
+# Contributor: Thomas Dziedzic < gostrc at gmail >
+# Contributor: joel schaerer <joel.schaerer@laposte.net>
+
+pkgname=insight-toolkit-git
+pkgver=5.4rc01.r92.gc3ae51517e
+pkgrel=1
+pkgdesc="Cross-platform system that provides developers with an extensive suite of software tools for image analysis"
+arch=(x86_64)
+url="https://itk.org/"
+license=(Apache)
+depends=(glibc gcc-libs libjpeg-turbo libpng zlib libtiff gdcm expat hdf5)
+makedepends=(cmake git eigen gtest)
+provides=(insight-toolkit)
+conflicts=(insight-toolkit)
+options=(!lto)
+source=("git+https://github.com/InsightSoftwareConsortium/ITK.git")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd ITK
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cmake -B build -S "ITK" -Wno-dev \
+    -DCMAKE_BUILD_TYPE:STRING=Release \
+    -DBUILD_TESTING:BOOL=OFF \
+    -DBUILD_EXAMPLES:BOOL=OFF \
+    -DBUILD_SHARED_LIBS:BOOL=ON \
+    -DCMAKE_INSTALL_PREFIX:FILEPATH=/usr \
+    -DModule_ITKReview:BOOL=ON \
+    -DITK_USE_SYSTEM_JPEG:BOOL=ON \
+    -DITK_USE_SYSTEM_PNG:BOOL=ON \
+    -DITK_USE_SYSTEM_ZLIB:BOOL=ON \
+    -DITK_USE_SYSTEM_TIFF:BOOL=ON \
+    -DITK_USE_SYSTEM_GDCM:BOOL=ON \
+    -DITK_LEGACY_SILENT:BOOL=ON \
+    -DCMAKE_CXX_FLAGS:STRING="-std=c++98" \
+    -DITK_USE_SYSTEM_LIBRARIES:BOOL=ON \
+    -DITK_USE_SYSTEM_EXPAT:BOOL=ON \
+    -DITK_USE_SYSTEM_FFTW:BOOL=ON \
+    -DITK_USE_SYSTEM_HDF5:BOOL=ON \
+    -DModule_ITKIOMINC:BOOL=ON \
+    -DModule_ITKIOTransformMINC:BOOL=ON \
+    -DModule_SimpleITKFilters:BOOL=ON
+
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}