Merged with official ABS kontact PKGBUILD

1 files changed, 34 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..fa553afc6f5d
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,34 @@
+# Merged with official ABS kontact PKGBUILD by João, 2021/07/20 (all respective contributors apply herein)
+# Maintainer: João Figueiredo & chaotic-aur <islandc0der@chaotic.cx>
+
+pkgname=kontact-git
+pkgver=21.11.40_r5346.ged3f1b15
+pkgrel=1
+pkgdesc="KDE Personal Information Manager"
+arch=($CARCH)
+url="https://kontact.kde.org"
+license=(GPL2)
+depends=(kontactinterface-git kmail-account-wizard-git grantleetheme-git)
+makedepends=(git extra-cmake-modules-git kdoctools-git boost)
+conflicts=(${pkgname%-git})
+provides=(${pkgname%-git})
+groups=(kde-applications-git kdepim-git)
+source=("git+https://github.com/KDE/${pkgname%-git}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd ${pkgname%-git}
+  _ver="$(grep -m1 'set(RELEASE_SERVICE_VERSION' CMakeLists.txt | cut -d '"' -f2 | tr - .)"
+  _ver=${_ver:-"$(grep -m1 'set(PIM_VERSION' CMakeLists.txt | cut -d '"' -f2 | tr - .)"}
+  echo "${_ver}_r$(git rev-list --count HEAD).g$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cmake -B build -S ${pkgname%-git} \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package() {
+  DESTDIR="$pkgdir" cmake --install build
+}