bump

1 files changed, 50 insertions, 28 deletions

diff --git a/PKGBUILD b/PKGBUILD
index 8f7ac67d73dd..b5a85d1bbe13 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,41 +1,63 @@
-# Maintainer: dmidge <quelque_ri1 at caramail point fr>
+# Contributor: dmidge <quelque_ri1 at caramail point fr>
+
 pkgname=ktechlab-git
-pkgver=0.3.7.rv0.40.0.r8.g34b41aa3
-pkgrel=3
-pkgdesc="KTechLab is an IDE for microcontrollers and electronics. It supports circuit simulation, program development for microcontrollers and simulating the programmed microcontroller together with its application circuit."
-arch=('x86_64' 'i686')
+pkgver=0.51.0.13.g7a62f7fd
+pkgrel=1
+pkgdesc="KTechLab is an IDE for microcontrollers and electronics. It supports circuit simulation, program development for microcontrollers and simulating the programmed microcontroller together with its application circuit. (GIT version)"
+arch=('x86_64')
 url="https://github.com/ktechlab/ktechlab"
 license=('GPL')
-#options=(!makeflags)
-depends=('qt4' 'kdelibs')
-makedepends=('git' 'cmake' 'gcc' 'gendesk' 'automoc4')
-source=(git+https://github.com/ktechlab/ktechlab
-        "$pkgname.desktop")
-md5sums=('SKIP'
-         'SKIP')
+depends=(
+  'gcc-libs' # libstdc++.so
+  'glibc' # libc.so libm.so
+  'kcompletion5' # libKF5Completion.so
+  'kconfig5' # libKF5ConfigCore.so libKF5ConfigGui.so
+  'kconfigwidgets5' # libKF5ConfigWidgets.so
+  'kcoreaddons5' # libKF5CoreAddons.so
+  'ki18n5' # libKF5I18n.so
+  'kiconthemes5' # libKF5IconThemes.so
+  'kio5' # libKF5KIOCore.so libKF5KIOWidgets.so
+  'kjobwidgets5' # libKF5JobWidgets.so
+  'kparts5' # libKF5Parts.so
+  'ktexteditor5' # libKF5TextEditor.so
+  'ktextwidgets5' # libKF5TextWidgets.so
+  'kwidgetsaddons5' # libKF5WidgetsAddons.so
+  'kwindowsystem5' # libKF5WindowSystem.so
+  'kxmlgui5' # libKF5XmlGui.so
+  'qt5-base' # libQt5Core.so libQt5Gui.so libQt5PrintSupport.so libQt5Widgets.so libQt5Xml.so
+  'qt5-serialport' # libQt5SerialPort.so
+  'gpsim' # libgpsim.so
+  'hicolor-icon-theme'
+)
+makedepends=(
+  'git'
+  'cmake'
+  'qt5-tools'
+)
+source=('git+https://github.com/ktechlab/ktechlab.git')
+sha256sums=('SKIP')
+options=('debug')
 
 pkgver() {
   cd ktechlab
-  echo "0.3.7.r`git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'`"
+  echo "$(git describe --long --tags | tr - . | tr -d v)"
 }
 
-#prepare() {
-#  gendesk -n --pkgname "$pkgname" --pkgdesc "$pkgdesc"
-#}
-
 build() {
-  cd ktechlab
-  if [ ! -d build ]; then
-    mkdir build
-  fi
+
+  cmake -S ktechlab -B build \
+    -DCMAKE_BUILD_TYPE=none \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DBUILD_TESTING=ON
+
+  cmake --build build
+}
+
+check() {
   cd build
-  cmake .. -DCMAKE_BUILD_TYPE=debugfull
-  make
+  ctest --output-on-failure
 }
 
 package() {
-  cd $srcdir/ktechlab/build
-  make DESTDIR="$pkgdir" install
-  install -d $pkgdir/usr/share/pixmaps
-  install -m664 $srcdir/ktechlab/icons/hi128-app-ktechlab.png $pkgdir/usr/share/pixmaps/$pkgname-icon.png
-} 
+  DESTDIR="${pkgdir}" cmake --install build
+}