Initial upload: lesma 0.6.0-1

1 files changed, 39 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..cb092cc5e57e
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,39 @@
+# Maintainer: "Amhairghin" Oscar Garcia Amor (https://ogarcia.me)
+
+pkgname=lesma
+pkgver=0.6.0
+pkgrel=1
+pkgdesc='A small and ultrasecure Lesspass database server written in Rust'
+arch=('arm' 'armv6h' 'armv7h' 'aarch64' 'i686' 'x86_64')
+url='https://gitlab.com/ogarcia/lesma'
+license=('GPL3')
+depends=('gcc-libs')
+makedepends=('rust')
+options=('!lto')
+backup=("etc/${pkgname}.toml")
+source=("https://gitlab.com/ogarcia/${pkgname}/-/archive/${pkgver}/${pkgname}-${pkgver}.tar.bz2"
+        "${pkgname}.toml"
+        "${pkgname}.service")
+b2sums=('011a07fd4b6652c936ba81e392f601d8bd162cb10e1ecf0a8b3cbc56917c77ba33a8fb307a82c901ea9466d0f82621ef7db86f3fbff49edc0b57b116bb9cc206'
+        '669031b846b817a48e7aa621df34fbf85102e8da6ab58e77ab6ac4abbb77d3632933881116f256e49a22cff3ecd52712ce9e34f451cef778d8e61762ad3609d2'
+        '6512f2d4fc6852cbcb96469890d15ab922d46eeeb6f25b234b074966f3a17b5748936fd5898a0e3c914b59f5b526595cff17f8abc856e58fb5cb4acd83ef2515')
+
+build() {
+  cd "${pkgbase}-${pkgver}"
+  cargo build --release --locked --target-dir=target
+}
+
+package() {
+  # binary
+  install -Dm755 "${srcdir}/${pkgbase}-${pkgver}/target/release/${pkgname}" \
+    "${pkgdir}/usr/bin/${pkgname}"
+  # conf
+  install -Dm644 "${srcdir}/${pkgname}.toml" "${pkgdir}/etc/${pkgname}.toml"
+  # service
+  install -Dm644 "${srcdir}/${pkgname}.service" "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
+  # templates and static directories
+  install -dm755 "${pkgdir}/usr/lib/${pkgname}"
+  cp -r "${srcdir}/${pkgbase}-${pkgver}/templates" \
+    "${srcdir}/${pkgbase}-${pkgver}/static" \
+    "${pkgdir}/usr/lib/${pkgname}"
+}