summarylogtreecommitdiffstats
path: root/PKGBUILD
diff options
context:
space:
mode:
authorLW-archlinux2015-12-23 16:05:17 +0100
committerLW-archlinux2015-12-23 16:05:17 +0100
commit8d0247cc7439a4905505567ff45aa37e6f61f279 (patch)
tree728c7bf94572baa7addad10b1cff74106061d8f5 /PKGBUILD
downloadaur-8d0247cc7439a4905505567ff45aa37e6f61f279.tar.gz
first version
Diffstat (limited to 'PKGBUILD')
-rw-r--r--PKGBUILD52
1 files changed, 52 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 00000000000..98901f3ce76
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,52 @@
+# Maintainer : Lone_Wolf <lonewolf at xs4all dot nl>
+# Contributor : Jan de Groot <jgc@archlinux.org>
+
+pkgname=libdrm-git
+_pkgname=libdrm
+pkgver=5795.b38a4b2
+pkgrel=2
+pkgdesc="Userspace interface to kernel DRM services, master git version"
+arch=(i686 x86_64)
+license=('custom')
+depends=('glibc' 'libpciaccess')
+makedepends=('valgrind' 'xorg-util-macros')
+checkdepends=('cairo' 'cunit')
+url="http://dri.freedesktop.org/"
+provides=('libdrm=2.4.66')
+replaces=('libdrm')
+conflicts=('libdrm')
+
+source=('libdrm::git://anongit.freedesktop.org/mesa/drm#branch=master'
+ COPYING)
+sha256sums=('SKIP'
+ '9631d4f694952e3e6ae5a05534c2e93e994e47d3413677a3a00e45c8cef6db93')
+
+pkgver() {
+ cd "${srcdir}/${_pkgname}"
+ echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)
+}
+
+prepare() {
+ cd ${_pkgname}
+
+ # pthread is useless in Linux
+ sed -i "/pthread-stubs/d" configure.ac
+}
+
+build() {
+ cd ${_pkgname}
+ ./autogen.sh --prefix=/usr --enable-udev
+ make
+}
+
+check() {
+ cd ${_pkgname}
+ make -k check
+}
+
+package() {
+ cd ${_pkgname}
+ make DESTDIR="$pkgdir" install
+ install -m755 -d "$pkgdir/usr/share/licenses/$pkgname"
+ install -m644 ${srcdir}/COPYING "$pkgdir/usr/share/licenses/$pkgname/"
+}