newpkg: libebur128-git 1.2.4.r43.g68abf1b-1

1 files changed, 42 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..9c18b7a6eb8d
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
+
+pkgname=libebur128-git
+pkgver=1.2.4.r43.g68abf1b
+pkgrel=1
+pkgdesc="A library implementing the EBU R128 loudness standard"
+arch=('i686' 'x86_64')
+url="https://github.com/jiixyj/libebur128"
+license=('MIT')
+depends=('glibc')
+makedepends=('git' 'cmake')
+provides=('libebur128')
+conflicts=('libebur128')
+options=('staticlibs')
+source=("git+https://github.com/jiixyj/libebur128.git")
+sha256sums=('SKIP')
+
+
+pkgver() {
+  cd "libebur128"
+
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "libebur128"
+
+  mkdir -p "_build" && cd "_build"
+  cmake \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX="/usr" \
+    -DCMAKE_INSTALL_LIBDIR="lib" \
+    "../"
+  make
+}
+
+package() {
+  cd "libebur128"
+
+  make -C "_build" DESTDIR="$pkgdir" install
+  install -Dm644 "COPYING" -t "$pkgdir/usr/share/licenses/libebur128"
+}