upgpkg 1.23.0; use upstream git source instead of fork; use gpg verification; vendor fork patches; execute tests; update deps

1 files changed, 40 insertions, 22 deletions

diff --git a/PKGBUILD b/PKGBUILD
index 7082489f8949..70d4ce3df063 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,35 +1,53 @@
-# Maintainer: Jasper van Bourgognie <louiecaulfield@gmail.com>
+# Maintainer: éclairevoyant
+# Contributor: Jasper van Bourgognie <louiecaulfield at gmail dot com>
+# Contributor: Andreas Radke <andyrtr at archlinux dot org>
 
-pkgname=libinput-three-finger-drag
-pkgver=1.19.3
-pkgrel=0
+_pkgname=libinput
+pkgname="$_pkgname-three-finger-drag"
+pkgver=1.23.0
+pkgrel=1
 pkgdesc="Input device management and event handling library"
-url="https://www.freedesktop.org/wiki/Software/libinput/"
+url="https://www.freedesktop.org/wiki/Software/$_pkgname/"
 arch=(x86_64)
 license=(custom:X11)
-provides=('libinput=1.19.3')
-conflicts=('libinput')
-depends=('mtdev' 'systemd' 'libevdev' 'libwacom' 'cmake' 'wayland-protocols')
+provides=("$_pkgname=$pkgver")
+conflicts=("$_pkgname")
+depends=(libevdev libwacom mtdev systemd)
 # upstream doesn't recommend building docs
-makedepends=('gtk3' 'meson' 'git') # 'doxygen' 'graphviz' 'python-sphinx' 'python-recommonmark'
-optdepends=('gtk3: libinput debug-gui'
+makedepends=(check git gtk4 meson wayland-protocols)
+checkdepends=(python-pytest)
+optdepends=('gtk4: libinput debug-gui'
             'python-pyudev: libinput measure'
             'python-libevdev: libinput measure')
-source=("libinput::git+https://github.com/jasper-van-bourgognie/libinput#tag=1.19.3-3fd")
-md5sums=('SKIP')
+source=("git+https://gitlab.freedesktop.org/$_pkgname/$_pkgname.git?signed#tag=c76559bb72b7ba3f1d3c80b72c8f686a2990cdaa"
+        0001-Three-finger-dragging-TFD-state-machine.patch
+        0002-Cleanup.patch
+        0003-TFD-add-debounce-state-for-touch-count-decrease.patch)
+b2sums=('SKIP'
+        '3eebc915aaccaec1a9164813ddea7b014a025baa7efff544700b48bb30d4fcd7827b871277b5b6ca0c3fde8b943fab2ccbc42f0f0d2da9b71a8c3f3c61a31765'
+        '44eba06688dc591aaed4f9962a9bf8c14a8faa16a25d2e09c0f9c05cd29444f342edbf78e62f4eebfaca1a67c5ea63ce0bd9f0441e211d09c30cf1ef2d559cd9'
+        'e3dd24b99ec9e7afeb0a328840bd240d2beb2cd1d01939320da32fa090418b716d84345e8be251c24f0e41278d535437a506bd6245848a83dfb05ee7dd9b5f14')
+validpgpkeys=('772183A93E722C0CD301BE62872C444A692EF9A5') # José Expósito <jose.exposito89@gmail.com>
+
+prepare() {
+	cd $_pkgname
+	patch -Np1 -i "$srcdir/0001-Three-finger-dragging-TFD-state-machine.patch"
+	patch -Np1 -i "$srcdir/0002-Cleanup.patch"
+	patch -Np1 -i "$srcdir/0003-TFD-add-debounce-state-for-touch-count-decrease.patch"
+}
 
 build() {
-  arch-meson libinput build \
-    -D b_lto=false \
-    -D udev-dir=/usr/lib/udev \
-    -D tests=false \
-    -D documentation=false
-  meson compile -C build
+	arch-meson $_pkgname build \
+		-D udev-dir=/usr/lib/udev \
+		-D documentation=false
+	meson compile -C build
 }
 
-package() {
-  DESTDIR="$pkgdir" meson install -C build
+check() {
+	meson test -C build --print-errorlogs
+}
 
-  install -Dvm644 libinput/COPYING \
-    "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+package() {
+	DESTDIR="$pkgdir" meson install -C build
+	install -Dvm644 $_pkgname/COPYING "$pkgdir/usr/share/licenses/$_pkgname/LICENSE"
 }