Split docs package. Update cmake commands.

1 files changed, 28 insertions, 14 deletions

diff --git a/PKGBUILD b/PKGBUILD
index ef57c671f172..3cb3670ad7d2 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,32 +1,46 @@
-# Maintainer : Daniel Bermond <dbermond@archlinux.org>
+# Maintainer: Daniel Bermond <dbermond@archlinux.org>
 
-pkgname=libopenshot-audio-git
-pkgver=0.1.8.r103.g12a1529
+pkgbase=libopenshot-audio-git
+pkgname=('libopenshot-audio-git' 'libopenshot-audio-docs-git')
+pkgver=0.3.2.r6.g08c2cdd
 pkgrel=1
 pkgdesc='A high-quality audio editing and playback library used by libopenshot (git version)'
 arch=('x86_64')
 url='https://www.openshot.org/'
 license=('LGPL3')
-depends=('alsa-lib' 'gcc-libs' 'glibc' 'zlib')
-makedepends=('git' 'cmake' 'doxygen' 'freetype2' 'libx11')
-provides=('libopenshot-audio' 'libopenshot-audio.so')
-conflicts=('libopenshot-audio')
+makedepends=('git' 'cmake' 'doxygen' 'alsa-lib' 'zlib' 'freetype2' 'libx11')
 source=('git+https://github.com/OpenShot/libopenshot-audio.git')
 sha256sums=('SKIP')
 
 pkgver() {
-    cd libopenshot-audio
-    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
+    git -C libopenshot-audio describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
 }
 
 build() {
     cmake -B build -S libopenshot-audio \
+        -G 'Unix Makefiles' \
+        -DCMAKE_BUILD_TYPE='None' \
         -DCMAKE_INSTALL_PREFIX:PATH='/usr' \
-        -Wno-dev \
-        ..
-    make -C build
+        -Wno-dev
+    cmake --build build
 }
 
-package() {
-    make -C build DESTDIR="$pkgdir" install
+package_libopenshot-audio-git() {
+    depends=('alsa-lib' 'gcc-libs' 'glibc' 'zlib')
+    provides=('libopenshot-audio' 'libopenshot-audio.so')
+    conflicts=('libopenshot-audio')
+    options=('!emptydirs')
+    
+    DESTDIR="$pkgdir" cmake --install build
+    mkdir -p docs-pkg/usr/share
+    mv "${pkgdir}/usr/share"/{doc,man} docs-pkg/usr/share
+}
+
+package_libopenshot-audio-docs-git() {
+    pkgdesc="$(sed 's/(\(git\)/(documentation; \1/' <<< "$pkgdesc")"
+    arch=('any')
+    provides=('libopenshot-audio-docs')
+    conflicts=('libopenshot-audio-docs')
+    
+    mv -T docs-pkg "$pkgdir"
 }