update to 1.2.r245.g514eedbc

* use upstream repo
* unbundle glm
* unbundle libchdr
* unbundle libzip
* unbundle miniupnpc
* unbundle xbyak
* unbundle xxhash
* unbundle zlib
* remove ccache

1 files changed, 46 insertions, 19 deletions

diff --git a/PKGBUILD b/PKGBUILD
index f9579143cf8f..444a497e17ed 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,41 +1,68 @@
 # Maintainer: Alexandre Bouvier <contact@amb.tf>
 # Contributor: Maxime Gauduin <alucryd@archlinux.org>
-_pkgname=libretro-flycast
+_reponame=flycast
+_pkgname=libretro-$_reponame
 pkgname=$_pkgname-git
-pkgver=r4464.4a913e06
+pkgver=1.2.r245.g514eedbc
 pkgrel=1
-pkgdesc='Sega Dreamcast core'
+pkgdesc="Sega Dreamcast core"
 arch=('i686' 'x86_64')
-url="https://github.com/libretro/flycast"
+url="https://github.com/flyinghead/$_reponame"
 license=('GPL2')
 groups=('libretro')
-depends=('libchdr' 'libgl' 'libretro-core-info' 'libzip' 'xxhash')
-makedepends=('git' 'libglvnd' 'zlib')
+depends=('libgl' 'libretro-core-info')
+makedepends=(
+	'cmake'
+	'git'
+	'glm'
+	'libchdr'
+	'libglvnd'
+	'libzip'
+	'miniupnpc'
+	'xbyak'
+	'xxhash'
+	'zlib'
+)
 provides=("$_pkgname")
 conflicts=("$_pkgname")
-options=('!lto') # https://github.com/libretro/flycast/issues/892
-source=("$_pkgname::git+$url.git")
-b2sums=('SKIP')
+source=(
+	"git+$url.git"
+	"$_pkgname-unbundle-libs.patch"
+)
+b2sums=(
+	'SKIP'
+	'602341ffaabf36382565ce780b88419feb6bf46ec7e2600631ead6a65c6d07edbdfbaea8c99ae9e53b85d260370eda0c06142b8b3149468508c4ad592a247a8d'
+)
 
 pkgver() {
-	cd $_pkgname
-	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+	cd $_reponame
+	git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
 }
 
 prepare() {
-	sed -E 's/^(\s*(CFLAGS|CXXFLAGS|LDFLAGS)\s*):=/\1+=/' -i $_pkgname/Makefile
+	cd $_reponame
+	patch -Np1 < ../$_pkgname-unbundle-libs.patch
+	rm -r core/deps/libretro-common/include/libchdr
 }
 
 build() {
-	make -C $_pkgname \
-		HAVE_OIT=1 \
-		SYSTEM_LIBCHDR=1 \
-		SYSTEM_LIBZIP=1 \
-		SYSTEM_XXHASH=1 \
-		SYSTEM_ZLIB=1
+	cd $_reponame
+	cmake -B ../build \
+		-DCMAKE_BUILD_TYPE=None \
+		-DCMAKE_INSTALL_BINDIR=lib/libretro \
+		-DCMAKE_INSTALL_PREFIX=/usr \
+		-DLIBRETRO=ON \
+		-Wno-dev
+	cmake --build ../build
 }
 
 package() {
+	depends+=(
+		'libchdr.so'
+		'libminiupnpc.so'
+		'libxxhash.so'
+		'libzip.so'
+	)
 	# shellcheck disable=SC2154
-	install -Dm644 -t "$pkgdir"/usr/lib/libretro $_pkgname/flycast_libretro.so
+	DESTDIR="$pkgdir" cmake --install build
 }