newpkg: libtorrent-ipv6 0.13.6-1

1 files changed, 47 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..c4a784ed2642
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,47 @@
+# $Id$
+# Maintainer: Allen Zhong <moeallenz@gmail.com>
+# Contributor: Gaetan Bisson <bisson@archlinux.org>
+# Contributor: Jaroslav Lichtblau <svetlemodry@archlinux.org>
+# Contributor: Daenyth <Daenyth+Arch [at] gmail [dot] com>
+# Contributor: Jeff Mickey <jeff@archlinux.org>
+# Contributor: sh__
+
+_pkgname=libtorrent
+pkgname=libtorrent-ipv6
+pkgver=0.13.6
+pkgrel=1
+pkgdesc='BitTorrent library with a focus on high performance and good code, with ipv6 support'
+url='http://rakshasa.github.io/rtorrent/'
+arch=('i686' 'x86_64')
+license=('GPL')
+depends=('openssl')
+conflicts=("${_pkgname}")
+provides=("${_pkgname}")
+source=("$_pkgname-$pkgver.tar.gz::https://github.com/rakshasa/${_pkgname}/archive/${pkgver}.tar.gz"
+        "${_pkgname}-ipv6.patch")
+sha1sums=('9ca6ca9698f81c758fe934b52374f23588a7cc78'
+          '3a0925101ada86a4b0cff03ce1c704fd8dfd80a3')
+
+prepare() {
+	cd "${srcdir}/${_pkgname}-${pkgver}"
+    patch -uNp1 -i "${srcdir}/${_pkgname}-ipv6.patch"
+	sed '/AM_PATH_CPPUNIT/d' -i configure.ac
+}
+
+build() {
+	cd "${srcdir}/${_pkgname}-${pkgver}"
+	./autogen.sh
+
+	export CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+	./configure \
+		--prefix=/usr \
+		--disable-debug \
+        --enable-ipv6
+
+	make
+}
+
+package() {
+	cd "${srcdir}/${_pkgname}-${pkgver}"
+	make DESTDIR="${pkgdir}" install
+}