Initial commit

1 files changed, 43 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..f7adff7d2c6b
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer:  twa022 <twa022 at gmail dot com>
+
+_pkgname=libxfce4windowing
+pkgname=${_pkgname}-devel
+pkgver=4.19.0+1+ga4062a9
+pkgrel=1
+pkgdesc="Windowing concept abstraction library for X11 and Wayland (git checkout)"
+arch=('i686' 'x86_64' 'armv7h' 'aarch64')
+url="https://docs.xfce.org/xfce/libxfce4windowing/start"
+license=('LGPL2.1')
+groups=('xfce4-git')
+depends=('gtk3' 'libwnck3')
+makedepends=('intltool' 'gtk-doc' 'gobject-introspection' 'xfce4-dev-tools' 'git')
+provides=("${_pkgname}=${pkgver%%+*}")
+conflicts=("${_pkgname}")
+source=("${_pkgname}::git+https://gitlab.xfce.org/xfce/${_pkgname}")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${_pkgname}"
+  git describe --long --tags | sed -r "s:^${_pkgname}.::;s/^v//;s/^xfce-//;s/-/+/g"
+}
+
+build() {
+  cd "${_pkgname}"
+
+  NOCONFIGURE=1 ./autogen.sh
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --libexecdir=/usr/lib \
+    --localstatedir=/var \
+    --disable-static \
+    --enable-gtk-doc \
+    --disable-debug
+  make
+}
+
+package() {
+  cd "${_pkgname}"
+
+  make DESTDIR="$pkgdir" install
+}