Converted package lilv-svn from AUR 3 to new lilv-git package

1 files changed, 44 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..7c6219c0bc9d
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>
+# Contributor: prettyvanilla <prettyvanilla@posteo.at>
+# Contributor: SpepS <dreamspepser at yahoo dot it>
+
+_pkgname=lilv
+pkgname="${_pkgname}-git"
+pkgver=0.22.1.r1071.59601f4
+pkgrel=1
+pkgdesc="A C library interface to the LV2 plug-in standard"
+arch=('i686' 'x86_64')
+url="http://drobilla.net/software/lilv"
+license=("custom:ISC")
+depends=('lv2' 'sratom' 'python-numpy')
+makedepends=('subversion' 'swig')
+optdepends=("bash-completion: auto-complete words")
+provides=("${_pkgname}")
+conflicts=("${_pkgname}" "${_pkgname}-svn")
+source=("${_pkgname}::git+http://git.drobilla.net/${_pkgname}.git")
+md5sums=('SKIP')
+
+pkgver() {
+  cd "${srcdir}/${_pkgname}"
+
+  local ver=`grep "^LILV_VERSION" wscript | cut -d "'" -f 2`
+  echo "$ver.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
+}
+
+build() {
+  cd "${srcdir}/${_pkgname}"
+
+  python waf configure --prefix=/usr \
+                       --configdir=/etc \
+                       --dyn-manifest \
+                       --bindings
+
+  python waf
+}
+
+package() {
+  cd "${srcdir}/${_pkgname}"
+
+  python waf install --destdir="${pkgdir}"
+  install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}