New versioning model.

1 files changed, 35 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..063dbea867fc
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,35 @@
+# Maintainer: Ian Brunelli (brunelli) <ian@brunelli.me>
+
+pkgname=lollypop-git
+_gitname=lollypop
+pkgver=0.9.15.r554.g40f35e8
+pkgrel=1
+pkgdesc='Music player for GNOME'
+arch=('i686' 'x86_64')
+license=('GPLv3')
+url="https://github.com/gnumdk/${_gitname}"
+depends=('gobject-introspection' 'gtk3' 'python-dbus' 'python-gobject' 'python-cairo' 'totem-plparser')
+makedepends=('git' 'gnome-common' 'intltool' 'itstool' 'python' 'yelp-tools')
+optdepends=('python-pylast: last.fm support')
+options=('!emptydirs')
+install=lollypop.install
+source=("git://github.com/gnumdk/${_gitname}.git")
+md5sums=('SKIP')
+conflicts=('lollypop')
+provides=("lollypop=$pkgver")
+
+pkgver() {
+	cd "${_gitname}"
+	git describe --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+	cd "$srcdir/${_gitname}"
+	./autogen.sh --prefix=/usr --disable-schemas-compile
+	make
+}
+
+package() {
+	cd "$srcdir/${_gitname}"
+	make DESTDIR="${pkgdir}" install
+}