A first attempt at packaging Chamsys Magicq.

1 files changed, 47 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..5352dc983616
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: Johan Förberg <johan@forberg.se>
+pkgname=magicq
+pkgver=1.7.2.4
+pkgrel=1
+pkgdesc='Lighting control software from Chamsys'
+arch=(x86_64)
+url='https://secure.chamsys.co.uk/magicq'
+groups=()
+depends=(ffmpeg-compat-55 libcups glu qt5-multimedia libusb-compat qt5-webkit
+         libarchive)
+options=('!strip') # Binaries are already stripped.
+
+# You can obtain this file from https://secure.chamsys.co.uk/download
+source=("local://magicq_${pkgver}_amd64.deb")
+sha1sums=('39472db2c562f7ab8b8d3a9fa03fc4fa3a1a3436')
+
+# I've been unable to find any formal license for Magicq. The website only
+# states that it's available free of charge. There don't seem to be any
+# restrictions on use, except that some features are disabled unless Chamsys
+# hardware is detected.
+license=(unknown)
+
+package() {
+    cd "$pkgdir"
+
+    bsdtar xf "$srcdir/data.tar.gz"
+
+    # We use the system libraries instead of the bundled binaries.
+    rm -rf opt/magicq/lib*.so*
+
+    # Magicq expects to be able to write these directories.
+    # The directory list comes from the debian package postinst.
+    chmod 777 opt/magicq
+
+    for dir in log show web thumbs backuparchive convert audio; do
+        mkdir -p "opt/magicq/$dir"
+        chmod -R 777 "opt/magicq/$dir"
+    done
+
+    # Fix permissions from .deb file.
+    find usr etc -type f -exec chmod 644 {} + , -type d -exec chmod 755 {} +
+
+    mkdir -p usr/bin
+    ln -s /opt/magicq/runmagicq.sh usr/bin/magicq
+    ln -s /opt/magicq/runmagichd.sh usr/bin/magichd
+    ln -s /opt/magicq/runmagicvis.sh usr/bin/magicvis
+}