Initial version

1 files changed, 65 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..e8af10517bf2
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,65 @@
+# Maintainer: drakkan <nicola.murino at gmail dot com>
+pkgname=mingw-w64-gst-rtsp-server-git
+pkgver=1.11.1.r5.cd4e675
+pkgrel=1
+_gitname=gst-rtsp-server
+pkgdesc="RTSP server library based on GStreamer (mingw-w64)"
+arch=(any)
+url="http://gstreamer.freedesktop.org/"
+license=('LGPL')
+depends=('mingw-w64-gstreamer-git' 'mingw-w64-gst-plugins-base-git')
+options=('!strip' '!buildflags' 'staticlibs')
+makedepends=('mingw-w64-configure' 'git')
+provides=('mingw-w64-gst-rtsp-server')
+conflicts=('mingw-w64-gst-rtsp-server')
+
+source=("$_gitname::git://anongit.freedesktop.org/gstreamer/$_gitname")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/$_gitname"
+  printf "%s" "$(git describe --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
+}
+
+prepare() {
+  cd $_gitname 
+  NOCONFIGURE=1 ./autogen.sh
+}
+
+_architectures="i686-w64-mingw32 x86_64-w64-mingw32"
+
+build() {
+  cd "${srcdir}/$_gitname"
+  for _arch in $_architectures; do
+    mkdir -p "build-${_arch}"
+    cd "build-${_arch}"
+    ${_arch}-configure \
+      --with-package-name="GStreamer RTSP Server Library (Arch Linux)" \
+      --with-package-origin="http://www.archlinux.org/" 
+
+    # https://bugzilla.gnome.org/show_bug.cgi?id=655517
+    sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+
+    make
+    cd ..
+  done
+}
+
+package() {
+  cd "${srcdir}/$_gitname"
+
+  for _arch in ${_architectures}; do
+    cd "build-${_arch}"
+    make DESTDIR="${pkgdir}" install
+
+    rm "$pkgdir"/usr/$_arch/lib/gstreamer-1.0/*.a
+    rm "$pkgdir"/usr/$_arch/lib/gstreamer-1.0/*.la
+
+    find "$pkgdir" -name '*.dll' -exec ${_arch}-strip --strip-unneeded {} \;
+    find "$pkgdir" -name '*.dll' -o -name '*.a' -exec ${_arch}-strip -g {} \;
+
+    cd ..
+  done
+}
+
+# vim: ts=2 sw=2 et: