Add static mingw-w64-qt6-* packages

1 files changed, 47 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..414271283304
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: Martchus <martchus@gmx.net>
+
+# All my PKGBUILDs are managed at https://github.com/Martchus/PKGBUILDs where
+# you also find the URL of a binary repository.
+
+pkgname=mingw-w64-qt6-5compat-static
+_qtver=6.0.0-beta3
+pkgver=${_qtver/-/}
+pkgrel=1
+arch=(any)
+url='https://www.qt.io'
+license=(GPL3 LGPL3 FDL custom)
+pkgdesc='Module that contains unsupported Qt 5 APIs (mingw-w64)'
+depends=('mingw-w64-qt6-base-static')
+makedepends=('mingw-w64-cmake-static' 'qt6-base' 'ninja')
+options=('!strip' '!buildflags' 'staticlibs' '!emptydirs')
+groups=(mingw-w64-qt6)
+_pkgfqn="qt5compat-everywhere-src-${_qtver}"
+source=("https://download.qt.io/development_releases/qt/${pkgver%.*}/${_qtver}/submodules/${_pkgfqn}.tar.xz")
+sha256sums=('94cb49919d875e05e6fc8286dbe63131b819ed05add0265619fe9abd7a32efab')
+
+_architectures='i686-w64-mingw32 x86_64-w64-mingw32'
+
+build() {
+  for _arch in ${_architectures}; do
+    export PKG_CONFIG=/usr/bin/$_arch-pkg-config
+    $_arch-cmake-static -G Ninja -B build-$_arch -S $_pkgfqn \
+      -DCMAKE_INSTALL_PREFIX:PATH="/usr/$_arch/static" \
+      -DFEATURE_pkg_config=ON
+    cmake --build build-$_arch
+  done
+}
+
+package() {
+  for _arch in ${_architectures}; do
+    DESTDIR="$pkgdir" cmake --install build-$_arch
+
+    find "$pkgdir/usr/$_arch" -iname '*.exe' -exec $_arch-strip --strip-all {} \;
+    find "$pkgdir/usr/$_arch" -iname '*.dll' -exec $_arch-strip --strip-unneeded {} \;
+    find "$pkgdir/usr/$_arch" -iname '*.a'   -exec $_arch-strip -g {} \;
+  done
+
+  install -d "$pkgdir"/usr/share/licenses
+  ln -s /usr/share/licenses/mingw-w64-qt6-base-static "$pkgdir"/usr/share/licenses/$pkgname
+
+}
+