Update(see below):

change source to HTTPS one
change pkgver to the latest commit date
remove mingw-w64-winpthreads-svn conflicts
add .gitignore

1 files changed, 33 insertions, 26 deletions

diff --git a/PKGBUILD b/PKGBUILD
index d5785d3113d1..72b7ffe92a4f 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,48 +1,55 @@
-# Maintainer: ant32 <antreimer@gmail.com>
+# Maintainer: pingplug <pingplug@foxmail.com>
+# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Contributor: ant32 <antreimer@gmail.com>
 # Contributor: rubenvb vanboxem <dottie> ruben <attie> gmail <dottie> com
+# Contributor: rkitover <rkitover@gmail.com>
+
+_targets="i686-w64-mingw32 x86_64-w64-mingw32"
+
 pkgname=mingw-w64-winpthreads-git
-pkgver=4.0.rc1.r7.gc440466
+pkgver=5.0.3.20180212
+_pkgver=5.0.3
 pkgrel=1
-pkgdesc='MinGW-w64 winpthreads library'
+pkgdesc='MinGW-w64 winpthreads library(git version)'
 arch=('any')
-url='http://mingw-w64.sourceforge.net'
+url='https://mingw-w64.org/doku.php'
 license=('custom')
 groups=('mingw-w64-toolchain' 'mingw-w64')
-depends=()
-makedepends=('git' 'mingw-w64-gcc-base' 'mingw-w64-binutils' 'mingw-w64-crt-git')
-optdepends=()
-provides=('mingw-w64-winpthreads' 'mingw-w64-headers-bootstrap' 'mingw-w64-winpthreads-svn')
-conflicts=('mingw-w64-headers-bootstrap' 'mingw-w64-winpthreads' 'mingw-w64-winpthreads-svn')
-replaces=('mingw-w64-headers-bootstrap' 'mingw-w64-winpthreads-svn')
-backup=()
+makedepends=('git' 'mingw-w64-gcc-base' 'mingw-w64-binutils' "mingw-w64-crt-git>=$pkgver")
+provides=("mingw-w64-winpthreads=$pkgver" 'mingw-w64-headers-bootstrap')
+conflicts=('mingw-w64-winpthreads' 'mingw-w64-headers-bootstrap')
+replaces=('mingw-w64-winpthreads' 'mingw-w64-headers-bootstrap')
 options=('!strip' '!buildflags' 'staticlibs' '!emptydirs')
-source=(git://git.code.sf.net/p/mingw-w64/mingw-w64)
-md5sums=(SKIP)
-
-_targets="i686-w64-mingw32 x86_64-w64-mingw32"
+source=('git+https://git.code.sf.net/p/mingw-w64/mingw-w64')
+sha256sums=('SKIP')
 
 pkgver() {
-  cd "$srcdir/mingw-w64"
-  ( set -o pipefail
-    git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
-    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
-  )
+  cd "${srcdir}/mingw-w64"
+  echo "${_pkgver}.`git log -1 --date=short --format=%cd | sed s/-//g`"
 }
 
 build() {
+  cd "${srcdir}"
   for _target in ${_targets}; do
     msg "Building ${_target} winpthreads..."
-    mkdir -p ${srcdir}/winpthreads-build-${_target} && cd ${srcdir}/winpthreads-build-${_target}
-    ${srcdir}/mingw-w64/mingw-w64-libraries/winpthreads/configure --prefix=/usr/${_target} \
-        --host=${_target} --enable-static --enable-shared
+    mkdir -p "winpthreads-build-${_target}" && pushd "winpthreads-build-${_target}"
+    ../mingw-w64/mingw-w64-libraries/winpthreads/configure \
+        --prefix=/usr/${_target} \
+        --host=${_target} \
+        --enable-static \
+        --enable-shared
     make
+    popd
   done
 }
 
 package() {
+  cd "${srcdir}"
   for _target in ${_targets}; do
-    cd ${srcdir}/winpthreads-build-${_target}
-    make DESTDIR=${pkgdir} install
+    msg "Installing ${_target} headers"
+    pushd "winpthreads-build-${_target}"
+    make DESTDIR="${pkgdir}" install
     ${_target}-strip --strip-unneeded "$pkgdir"/usr/${_target}/bin/*.dll
+    popd
   done
-}
\ No newline at end of file
+}