Add monobit-git

1 files changed, 42 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..fd1385b6da65
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,42 @@
+# Maintainer: taotieren <cadmin@taotieren.com>
+
+pkgname=monobit-git
+pkgver=0.35.0.r0.gd4d2519
+pkgrel=1
+pkgdesc='Tools for working with monochrome bitmap fonts'
+url='https://github.com/robhagemans/monobit'
+license=('MIT')
+arch=(any)
+_pydeps=(reportlab
+        pillow
+        python-bidi
+        arabic-reshaper
+        hatchling
+        uniseg
+        fonttools)
+depends=(python
+         "${_pydeps[@]/#/python-}")
+makedepends=(git
+            python-{build,installer}
+             python-setuptools-scm
+             python-wheel)
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("$pkgname::git+$url.git")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "$pkgname"
+    git describe --long --tags | sed 's/^v//g;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+    cd "$pkgname"
+    python -m build -wn
+}
+
+package() {
+    cd "$pkgname"
+    python -m installer -d "$pkgdir" dist/*.whl
+}
+