Initial commit. 0.20-2.

1 files changed, 54 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..491cc0c77ac1
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,54 @@
+# Maintainer: Melvin Vermeeren <mail@mel.vin>
+
+pkgname=mpd-sacd
+pkgver=0.20
+pkgrel=2
+pkgdesc='Flexible, powerful, server-side application for playing music'
+url='http://git.musicpd.org/cgit/manisiutkin/mpd.git/'
+license=('GPL')
+arch=('i686' 'x86_64')
+depends=('libao' 'ffmpeg' 'libmodplug' 'audiofile' 'libshout' 'libmad' 'curl' 'faad2'
+         'sqlite' 'jack' 'libmms' 'wavpack' 'avahi' 'libid3tag' 'yajl' 'libmpdclient'
+         'icu' 'libupnp' 'libnfs' 'libsamplerate' 'libsoxr' 'smbclient')
+makedepends=('boost' 'doxygen')
+conflicts=('mpd')
+provides=('mpd=0.20')
+source=('git://git.musicpd.org/manisiutkin/mpd.git'
+        'tmpfiles.d'
+        'conf')
+sha1sums=('SKIP'
+          'f4d5922abb69abb739542d8e93f4dfd748acdad7'
+          '291fd5cda9f0845834a553017327c4586bd853f6')
+
+backup=('etc/mpd.conf')
+install=install
+
+build() {
+	cd "${srcdir}/mpd"
+	./autogen.sh
+	./configure \
+		--prefix=/usr \
+		--sysconfdir=/etc \
+		--enable-libmpdclient \
+		--enable-jack \
+		--enable-soundcloud \
+		--enable-pipe-output \
+		--enable-pulse \
+		--enable-sacdiso \
+		--enable-dvdaiso \
+		--disable-sidplay \
+		--with-systemdsystemunitdir=/usr/lib/systemd/system
+	make
+}
+
+package() {
+	cd "${srcdir}/mpd"
+	make DESTDIR="${pkgdir}" install
+	install -Dm644 ../conf "${pkgdir}"/etc/mpd.conf
+	install -Dm644 ../tmpfiles.d "${pkgdir}"/usr/lib/tmpfiles.d/mpd.conf
+	install -d -g 45 -o 45 "${pkgdir}"/var/lib/mpd{,/playlists}
+
+	install -Dm644 "${pkgdir}"/usr/lib/systemd/{system,user}/mpd.service
+	sed '/\[Service\]/a User=mpd' -i "${pkgdir}"/usr/lib/systemd/system/mpd.service
+	sed '/WantedBy=/c WantedBy=default.target' -i "${pkgdir}"/usr/lib/systemd/{system,user}/mpd.service
+}