initial commit

1 files changed, 30 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..fdd184a315a1
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,30 @@
+# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
+pkgname=nemo-ext-git-git
+pkgver=1.3.r16.g5389549
+pkgrel=1
+pkgdesc="Nemo extension to add important information about the current git directory"
+arch=('i686' 'x86_64')
+url="https://github.com/bilelmoussaoui/nautilus-git"
+license=('GPL3')
+depends=('git' 'gobject-introspection' 'gtk3' 'nemo-python')
+makedepends=('gnome-common' 'meson' 'intltool')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("${pkgname%-git}::git+https://github.com/bilelmoussaoui/nautilus-git")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$srcdir/${pkgname%-git}"
+	printf "%s" "$(git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g')"
+}
+
+build() {
+	cd "$srcdir/${pkgname%-git}"
+	arch-meson builddir -Dpost_install=false -Dfile_manager=nemo
+	ninja -C builddir
+}
+
+package() {
+	cd "$srcdir/${pkgname%-git}"
+	DESTDIR="$pkgdir" ninja -C builddir install
+}